# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

data "aws_iam_policy_document" "jenkins_sfn_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "states:ListExecutions",
      "states:StartExecution",
    ]
    resources = [
      aws_sfn_state_machine.sfn_sr_delivery_tiktok.arn,
    ]
  }
}

data "aws_iam_policy_document" "jenkins_lambda_invoke_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction"
    ]
    resources = [
      module.lambda_sr_add_version.lambda_arn,
    ]
  }
}

data "aws_iam_policy_document" "jenkins_s3_interm_delivery_bucket_delivery_worker_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject",
      "s3:GetObjectTagging",
      "s3:PutObject",
      "s3:PutObjectTagging",
      "s3:DeleteObject",
    ]

    resources = [
      "${module.s3_interm_delivery_bucket.s3_bucket_arn_output}/*"
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:ListBucket"
    ]

    resources = [
      module.s3_interm_delivery_bucket.s3_bucket_arn_output
    ]

  }
}

# Jenkins agents will assume this role
resource "aws_iam_role" "jenkins_role" {
  name               = "${var.environment}-sound-recordings-jenkins-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# SFN invoke policy.
resource "aws_iam_policy" "jenkins_sfn_invoke_policy" {
  name   = "SFN-${var.environment}-sound-recordings-jenkins-policy"
  policy = data.aws_iam_policy_document.jenkins_sfn_policy_document.json
}

# Lambda invoke policy
resource "aws_iam_policy" "jenkins_lambda_invoke_policy" {
  name   = "Lambda-${var.environment}-sound-recordings-jenkins-invoke-only-policy"
  policy = data.aws_iam_policy_document.jenkins_lambda_invoke_policy_document.json
}

# S3 policy
resource "aws_iam_policy" "jenkins_s3_interm_delivery_bucket_delivery_worker_policy" {
  name   = "S3-${var.environment}-interm-delivery-bucket-jenkins-delivery-policy"
  policy = data.aws_iam_policy_document.jenkins_s3_interm_delivery_bucket_delivery_worker_policy_document.json
}

# Attach SFN policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "jenkins_sfn_invoke_policy_attachment" {
  role       = aws_iam_role.jenkins_role.id
  policy_arn = aws_iam_policy.jenkins_sfn_invoke_policy.arn
}

# Attach lambda policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "jenkins_lambda_invoke_policy_attachment" {
  role       = aws_iam_role.jenkins_role.id
  policy_arn = aws_iam_policy.jenkins_lambda_invoke_policy.arn
}

# Attach S3 policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "jenkins_s3_interm_delivery_policy_attachment" {
  role       = aws_iam_role.jenkins_role.id
  policy_arn = aws_iam_policy.jenkins_s3_interm_delivery_bucket_delivery_worker_policy.arn
}