module "lambda_sr_add_version_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  application_family = var.application_family
  environment        = var.environment
  platform           = "python"
  service_name       = var.sr_add_version_function_name
  teams              = [var.environment]
}

module "lambda_sr_add_version_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.sr_add_version_function_name
}

data "aws_iam_policy_document" "s3_sr_versions_lambda_sr_add_version_policy_document" {
  statement {
    actions = [
      "s3:PutObject",
      "s3:GetObject",
      "s3:GetObjectVersion",
      "s3:GetBucketVersioning"
    ]

    resources = [
      "arn:aws:s3:::${var.environment}-${var.sr_versions_bucket}/*"
    ]
  }

  statement {
    actions = [
      "s3:ListBucket",
    ]

    resources = [
      "arn:aws:s3:::${var.environment}-${var.sr_versions_bucket}"
    ]
  }
}

resource "aws_iam_policy" "s3_sr_versions_lambda_sr_add_version_policy" {
  name   = "S3-${var.environment}-${var.sr_versions_bucket}-lambda-sr-add-version-RW-policy"
  policy = data.aws_iam_policy_document.s3_sr_versions_lambda_sr_add_version_policy_document.json
}

module "lambda_sr_add_version" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.1.0"

  application_family       = var.application_family
  datadog_advanced_enabled = true
  environment              = var.environment
  lambda_name              = var.sr_add_version_function_name
  lambda_description       = "Handle sound recording version"
  lambda_function_timeout  = var.lambda_max_timeout
  use_container_image      = true
  vpc_id                   = module.vpc_info.vpc_id
  vpc_subnet_ids           = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    module.lambda_sr_add_version_owsrequest.policy_arn_output,
    aws_iam_policy.s3_sr_versions_lambda_sr_add_version_policy.arn
  ]

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
    NEW_ELIGIBILITY_FLOW = var.new_eligibility_flow
    KAFKA_TOPIC = var.kafka_new_version_topic
    KAFKA_BROKERS = var.kafka_brokers
  }

  lambda_function_reserved_concurrent_executions = "300"
}


module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = var.sr_add_version_function_name
  application_family = var.application_family
}

module "datadog_lambda_sr_add_version_dashboards" {
  source                                = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.4"
  service_name                          = var.sr_add_version_function_name
  environment                           = var.environment
  lambda_invocation_monitor_enabled     = false
  lambda_error_monitor_enabled          = true
  notification_endpoints                = var.slack_alert_channel
  lambda_error_critical_number          = 15
  lambda_error_critical_recovery_number = null
}