# used by https://scheduler.theorchard.io/job/content-sr-ddex-generator/
data "aws_iam_policy_document" "jenkins_ddex_generator_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

data "aws_iam_policy_document" "jenkins_ddex_generator_s3_policy" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:ListBucket",
      "s3:GetObjectVersion",
    ]
    resources = [
      "arn:aws:s3:::${var.environment}-sr-versions-bucket/*",
      "arn:aws:s3:::${var.environment}-sr-versions-bucket",
    ]
    effect = "Allow"
  }
}

resource "aws_iam_role" "ddex_generate_assume_role" {
  name               = "${var.environment}-ddex-generate-s3-assume-role"
  description        = "Role for Jenkins ddex-generator to access S3 version bucket"
  assume_role_policy = data.aws_iam_policy_document.jenkins_ddex_generator_assume_role_policy.json
}

resource "aws_iam_role_policy" "jenkins_ddex_generator_policy" {
  name   = "${var.environment}-jenkins-ddex-generator-s3-policy"
  role   = aws_iam_role.ddex_generate_assume_role.id
  policy = data.aws_iam_policy_document.jenkins_ddex_generator_s3_policy.json
}


# Used by https://pipeline.theorchard.io/job/content-sound-recording-redelivery/
data "aws_iam_policy_document" "jenkins_sr_redelivery_assume_role_policy_document" {
  statement {
    actions = ["sts:AssumeRole"]
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
        "arn:aws:iam::086679231553:role/shared-pipeline-jenkins-task-role",
      ]
    }
    effect = "Allow"
  }
}

resource "aws_iam_role" "jenkins_sr_redelivery_role" {
  name               = "${var.environment}-jenkins-sr-redelivery-role"
  description        = "Role for Jenkins jobs to execute Step Function"
  assume_role_policy = data.aws_iam_policy_document.jenkins_sr_redelivery_assume_role_policy_document.json
  max_session_duration = 43200 # 12 hours - Required for the content-sound-recording-redelivery script to run successfully
}

data "aws_iam_policy_document" "jenkins_sr_redelivery_executor_policy_document" {
  statement {
    actions = [
      "states:StartExecution",
      "states:ListExecutions"
    ]
    resources = [
      aws_sfn_state_machine.sfn_sr_delivery_tiktok.arn,
      aws_sfn_state_machine.sfn_sr_delivery_youtube.arn
    ]
    effect = "Allow"
  }
}

data "aws_iam_policy_document" "jenkins_sr_redelivery_s3_policy_document" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:ListBucket",
      "s3:GetObjectVersion"
    ]
    resources = [
      "arn:aws:s3:::${var.environment}-sr-versions-bucket/*",
      "arn:aws:s3:::${var.environment}-sr-versions-bucket",
    ]
    effect = "Allow"
  }
}

resource "aws_iam_role_policy" "jenkins_sr_redelivery_executor_policy" {
  name   = "${var.environment}-jenkins-sr-redelivery-executor-policy"
  role   = aws_iam_role.jenkins_sr_redelivery_role.id
  policy = data.aws_iam_policy_document.jenkins_sr_redelivery_executor_policy_document.json
}
resource "aws_iam_role_policy" "jenkins_sr_redelivery_s3_policy" {
  name   = "${var.environment}-jenkins-sr-redelivery-executor-s3-policy"
  role   = aws_iam_role.jenkins_sr_redelivery_role.id
  policy = data.aws_iam_policy_document.jenkins_sr_redelivery_s3_policy_document.json
}


# Policies for sr-delivery-upload, e.g. mocking deliveries in QA by delivering to our own S3
data "aws_iam_policy_document" "sr_delivery_upload_assume_role_policy" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type        = "AWS"
      identifiers = var.sr_delivery_upload_assume_role_arns
    }
  }
}

module "sr_delivery_upload_group" {
  source = "git@github.com:theorchard/terraform-iam-policies.git//modules/groups?ref=1.18.0"
  group_name = var.sr_delivery_upload_group_name
  iam_roles_to_access = [
    aws_iam_role.sr_delivery_upload_lambda_sr_delivery_tiktok_role.arn,
    aws_iam_role.sr_delivery_upload_lambda_sr_delivery_youtube_role.arn
  ]
  users = [
    "yostapyuk",
    "amontoya",
    "jbertran",
    "nlittmann",
    "jmarais",
    "rshield"
  ]
  application_families_to_access = [
    "sound-recordings"
  ]
}

data "aws_iam_group" "sr_delivery_upload_group" {
  group_name = var.sr_delivery_upload_group_name
}