data "aws_iam_policy_document" "ar_to_ddb_sync_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:PutObject"
    ]
    resources = [
      "${data.aws_s3_bucket.orcd_bucket.arn}/vector3/vector-orders/*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "sqs:GetQueueAttributes",
      "sqs:GetQueueUrl",
      "sqs:ListQueueTags",
      "sqs:TagQueue",
      "sqs:UntagQueue",
      "sqs:SendMessageBatch",
      "sqs:SendMessage"
    ]
    resources = [
      module.assets_to_download_queue.queue_arn
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "dynamodb:PutItem"
    ]
    resources = [
      module.ar_to_ddb_sync_dynamodb_table.aws_dynamodb_table_arn
    ]
  }
}

resource "aws_iam_policy" "ar_to_ddb_sync_lambda_policy" {
  name        = "${var.environment}-${var.lambda_ar_to_ddb_sync_name}"
  description = "ar-to-ddb-sync lambda policy"
  policy      = data.aws_iam_policy_document.ar_to_ddb_sync_policy_document.json
}

module "lambda_ar_to_ddb_sync" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.9"

  environment                 = var.environment
  application_family          = var.application_family
  lambda_name                 = "${var.service_name}-${var.lambda_ar_to_ddb_sync_name}"
  lambda_description          = "The new delivery ar-to-ddb-sync script."
  lambda_function_memory_size = var.lambda_memory_size
  cloudwatch_event_enabled    = true
  cloudwatch_event_schedule   = "rate(1 minute)"
  lambda_function_timeout     = var.lambda_default_timeout
  vpc_id                      = module.vpc_info.vpc_id
  vpc_subnet_ids              = module.vpc_info.default_private_subnet_ids
  use_container_image         = true
  datadog_advanced_enabled    = true
  datadog_enabled             = true

  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions

  iam_managed_policy_attachments = [
    aws_iam_policy.ar_to_ddb_sync_lambda_policy.arn,
    module.ar_to_ddb_sync_owsrequest.policy_arn_output,
  ]

  lambda_function_environment_variables = {
    Environment            = var.environment
    AR_MYSQL_DATABASE      = var.ar_mysql_database
    AR_MYSQL_HOST          = var.ar_mysql_host
    AR_MYSQL_PORT          = var.ar_mysql_port
    AR_MYSQL_USER          = "vect_obtn_orders"
    DDB_WRITE_MAX_ATTEMPTS = 5
    ORDERS_DDB_TABLE       = module.ar_to_ddb_sync_dynamodb_table.aws_dynamodb_table_id
    ORDERS_S3_BUCKET       = data.aws_s3_bucket.orcd_bucket.id
    ORDER_ENCODER_ID_LIST  = var.order_encoder_id_list
    SENTRY_DSN             = module.sentry_ar_to_ddb_sync_lambda.sentry_key_dsn_public_output
    PHYSICAL_LOCATIONS     = "9"
  }
}