module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/martech-snowflake-salesforce-node/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}


module "service_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.service_name
  application_family = var.application_family
}

module "services_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "service_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.7.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  aws_region                               = var.region
  commit_sha                               = "latest"
  container_port                           = var.container_port
  task_type                                = "web_service"
  desired_task_count                       = 1
  task_cpu                                 = 512
  task_memory                              = 1024
  maximum_capacity                         = 1
  minimum_capacity                         = 1
  route53_zone_id                          = data.aws_route53_zone.theorchard_io.zone_id
  load_balancer_access_logs_s3_bucket_name = data.aws_s3_bucket.logs.id
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.id)[1]
  non_ecr_image                            = "086679231553.dkr.ecr.${var.region}.amazonaws.com/${var.application_family}-${var.service_name}:latest"
  custom_waf_arn                           = module.custom_waf.waf_blocking_arn_output

  fargate_service_subnets         = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets           = module.vpc_info.default_private_subnet_ids
  additional_lb_target_group_arns = [aws_lb_target_group.proxy.arn]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      AUTH0_DOMAIN = "qa-orchard.auth0.com"
    },
    {
      AUTH0_API_AUDIENCE = "https://qa-martech-snowflake-salesforce-node"
    },
    {
      NODE_ENV = "production"
    },
    {
      DD_LOGS_INJECTION = true
    },
    {
      SENTRY_DSN = module.service_sentry_project.sentry_key_dsn_public_output
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    }
  ]
  secrets = [
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
    {
      SNOWFLAKE_PASSPHRASE = "${var.environment}/${var.service_name}/SNOWFLAKE_PASSPHRASE"
    },
    {
      AES_KEY = "${var.environment}/${var.service_name}/AES_KEY"
    },
  ]

}

module "service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.6"

  environment  = var.environment
  service_name = var.service_name

  environment_type                  = "fargate"
  notification_endpoints            = var.alert_channel
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  application_family                = var.application_family
  escalation_notification_endpoints = var.alert_channel
}