module "kafka_dynamodb_sink_basic" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.5.4"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  application_family                       = var.application_family
  service_name                             = var.service_name
  aws_region                               = var.region
  non_ecr_image                            = "086679231553.dkr.ecr.us-east-1.amazonaws.com/kc-ddb-sink:latest"
  service_platform_version                 = "1.4.0"
  desired_task_count                       = 1
  minimum_capacity                         = 1
  maximum_capacity                         = 1
  task_cpu                                 = 1024
  task_memory                              = 3072
  container_port                           = 8083
  health_check_grace_period_seconds        = 300
  container_start_period_seconds           = 300
  blocking_waf_enabled                     = true
  health_check_path                        = "/connectors/${var.connector_name_basic}"
  web_service_health_check_command         = "[ \"$(curl -s -f http://localhost:8083/connectors/${var.connector_name_basic}/tasks/0/status | jq -r .state)\" == 'RUNNING' ] || exit 1"
  vpc_id                                   = module.vpc_info.vpc_id
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  fargate_service_subnets                  = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                    = module.vpc_info.default_private_subnet_ids
  iam_managed_policy_attachments = [
    aws_iam_policy.dynamodb_write_policy_basic.arn
  ]

  datadog_custom_image = "086679231553.dkr.ecr.${var.region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = var.service_name
    },
    {
      CONNECTOR_TYPE = "default_sink"
    },
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      CONNECTOR_NAME = "${var.connector_name_basic}"
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = "${var.environment}-${var.service_name}"
    },
    {
      SERVICE_NAME = "${var.service_name}"
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.kafka_brokers
    },
    {
      AWS_REGION = var.region
    },
    {
      DYNAMODB_TABLE = "${var.environment}_${var.dynamodb_table_name}"
    },
    {
      KAFKA_TOPICS = var.ownership_ingest_reporting_topic
    },
    {
      DLQ_TOPIC_NAME = var.ddb_sink_dlq_topic_name
    },
    {
      DYNAMODB_OPERATION = "PutItem"
    },
    {
      DEBUG_MODE = "true"
    },
    {
      CONNECT_LOG4J_ROOT_LOGLEVEL = "ERROR"
    },
    {
      CONNECT_LOG4J_LOGGERS = "org.reflections=ERROR,org.eclipse.jetty=ERROR,kafka=ERROR,org.apache.kafka=ERROR,org.apache.zookeeper=ERROR,org.apache.kafka.connect.runtime.WorkerSinkTask=ERROR"
    },
    {
      USE_DEFAULT_CREDENTIALS_PROVIDER = "true"
    },
  ]
}


# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "allow_intra_cluster_communication_dynamodb_sink_basic" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kafka_dynamodb_sink_basic.fargate_security_group_id
  self              = true
  type              = "ingress"
}

resource "aws_iam_policy" "dynamodb_write_policy_basic" {
  name        = "${var.environment}-${var.service_name}-dynamodb-stream-policy"
  description = "Policy for write access to DynamoDB"
  policy      = data.aws_iam_policy_document.dynamodb_write_policy_basic.json
}

data "aws_iam_policy_document" "dynamodb_write_policy_basic" {
  statement {
    effect = "Allow"
    actions = [
      "dynamodb:DescribeTable",
      "dynamodb:PutItem",
    ]
    resources = [
      data.aws_dynamodb_table.dynamodb_sink_basic.arn
    ]
  }
}

data "aws_dynamodb_table" "dynamodb_sink_basic" {
  name = "${var.environment}_${var.dynamodb_table_name}"
}

data "aws_iam_policy_document" "dynamodb_read_policy_basic" {
  statement {
    effect = "Allow"
    actions = [
      "dynamodb:Get*",
      "dynamodb:List*",
      "dynamodb:BatchGetItem",
      "dynamodb:Scan",
      "dynamodb:Query",
      "dynamodb:ConditionCheckItem",
    ]
    resources = [
      data.aws_dynamodb_table.dynamodb_sink_basic.arn
    ]
  }
}

resource "aws_iam_policy" "dynamodb_read_policy_basic" {
  name        = "${var.environment}-${var.service_name}-ddb-read-policy"
  description = "Policy for read access to DynamoDB"
  policy      = data.aws_iam_policy_document.dynamodb_read_policy_basic.json
}

module "fargate_dashboard_ddb" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.12.0"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  service_name       = var.service_name
  connector_type     = "default_sink"

  environment_type = "fargate"

  notification_endpoints            = var.slack_alert_channel
  escalation_notification_endpoints = "@slack-kafka-data-highway-alerts"
  healthy_tasks_monitor_enabled     = false
  monitor_kafka_topics              = [var.ownership_ingest_reporting_topic]
  dlq_topic_name                    = var.ddb_sink_dlq_topic_name
  service_cpu_monitor_enabled       = true
  error_monitor_enabled             = true

  healthy_tasks_critical_number = 0

  teams = [var.team_name]
}