module "lambda-nr-ownership-ingest-ar-track-filter" {
  source                      = "git@github.com:theorchard/terraform-lambda.git//?ref=4.0.1"
  environment                 = var.environment
  lambda_name                 = var.ar_track_filter_lambda_name
  lambda_description          = "Consumes cdc art relation track data."
  lambda_function_timeout     = "900"
  use_container_image         = true
  vpc_subnet_ids              = module.vpc_info.default_private_subnet_ids
  vpc_enabled                 = true
  vpc_id                      = module.vpc_info.vpc_id
  datadog_advanced_enabled    = true
  application_family          = var.application_family
  lambda_function_memory_size = var.lambda_memory_size
  splitio_enabled             = true

  msk_event_enabled                            = var.msk_event_enabled
  event_source_mapping_msk_cluster_name        = var.trigger_msk_cluster_name
  event_source_mapping_msk_cluster_uuid        = var.trigger_msk_cluster_uuid
  event_source_mapping_batch_size              = 10
  kafka_topics                                 = [var.ar_track_topic]
  event_source_mapping_starting_position       = "LATEST"
  event_source_mapping_filter_criteria_pattern = jsonencode({ "value" : { "payload" : { "op" : [{ "anything-but" : ["c"] }] } } })

  lambda_function_environment_variables = {
    Environment        = var.environment
    DD_LAMBDA_HANDLER  = "app.handler"
    SENTRY_DSN         = module.lambda_nr_ownership_ingest_ar_track_filter_sentry_project.sentry_key_dsn_public_output
    SPLIT_API_KEY_PATH = "${var.environment}/split/API_KEY"
    BUCKET_NAME        = data.aws_s3_bucket.s3_bucket.bucket
    KAFKAJS_LOG_LEVEL  = "nothing"
    KAFKA_BROKERS      = var.kafka_brokers
    SQS_QUEUE_URL      = module.sqs_sync_tracks_queue.queue_url
    LOGGER_LEVEL       = "info"
    SEND_TO_SQS        = true
  }

  lambda_function_reserved_concurrent_executions = 1

  iam_managed_policy_attachments = [
    data.aws_iam_policy.ownership_ingestion_bucket_rw_policy.arn,
    module.sqs_sync_tracks_queue.sqs_minimal_policy_arn_output
  ]
}

module "lambda_nr_ownership_ingest_ar_track_filter_sentry_project" {
  source                       = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"
  service_name                 = var.ar_track_filter_lambda_name
  secrets_manager_service_name = var.ar_track_filter_lambda_name
  environment                  = var.environment
  platform                     = "node"
  application_family           = var.application_family
}

module "datadog_lambda_nr_ownership_ingest_ar_track_filter_dashboards" {
  source                 = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.4"
  service_name           = var.ar_track_filter_lambda_name
  environment            = var.environment
  notification_endpoints = var.slack_alert_channel
  teams                  = [var.team_name]
}