# state machine initiated with this policy/role.
data "aws_iam_policy_document" "assume_role_for_state_machine_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.${var.region}.amazonaws.com",
      ]
    }
  }
}

resource "aws_iam_role" "state_machine_role" {
  name               = "${var.environment}-${var.state_machine_name}-state-machine-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_state_machine_policy.json
}

data "aws_iam_policy_document" "invoke_lambda_policy_for_state_machine" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      module.lambda_nr_ownership_ingest_participant_deduplicator.lambda_arn,
      module.lambda_nr_ownership_ingest_participant_writer.lambda_arn,
      module.lambda_nr_ownership_ingest_product_deduplicator.lambda_arn,
      module.lambda-nr-ownership-ingest-product-writer.lambda_arn,
      module.lambda_nr_ownership_ingest_sr_deduplicator.lambda_arn,
      module.lambda-nr-ownership-ingest-sr-writer.lambda_arn,
      module.lambda_nr_ownership_ingest_rules_writer.lambda_arn,
      module.lambda_nr_ownership_ingest_contributor_deduplicator.lambda_arn,
      module.lambda_nr_ownership_ingest_contributor_writer.lambda_arn,
      module.lambda_nr_ownership_ingest_finalizer.lambda_arn,
    ]
  }
}

# Policy that gives the state machine role permission to start Distributed Map Executions
data "aws_iam_policy_document" "start_execution_state_machine_policy_doc" {
  statement {
    actions = [
      "states:StartExecution",
      "states:ListExecutions",
    ]

    resources = [
      aws_sfn_state_machine.state_machine.arn
    ]
  }
}

resource "aws_iam_policy" "start_execution_state_machine_policy" {
  name        = "StepFunctions-${var.environment}-${var.state_machine_name}-StartExecution"
  description = "Invoke Distributed Map Child State Machines"
  policy      = data.aws_iam_policy_document.start_execution_state_machine_policy_doc.json
}


# Policy that gives the state machine role permission to invoke lambdas
resource "aws_iam_role_policy" "invoke_lambda_role_policy" {
  name   = "${var.environment}-${var.state_machine_name}-invoke-lambda-role-policy"
  role   = aws_iam_role.state_machine_role.id
  policy = data.aws_iam_policy_document.invoke_lambda_policy_for_state_machine.json
}

resource "aws_iam_role_policy_attachment" "other_policy_attachment" {
  for_each = toset([
    data.aws_iam_policy.ownership_ingestion_bucket_rw_policy.arn,
    aws_iam_policy.start_execution_state_machine_policy.arn,
  ])
  role       = aws_iam_role.state_machine_role.id
  policy_arn = each.key
}

resource "aws_sfn_state_machine" "state_machine" {
  name     = "${var.environment}-${var.state_machine_name}"
  role_arn = aws_iam_role.state_machine_role.arn
  definition = templatefile("${path.module}/ingestion_workflow.json", {
    # add all variables here that will be used by ingestion_workflow.json.
    participant_deduplicator_arn = module.lambda_nr_ownership_ingest_participant_deduplicator.lambda_arn,
    participant_writer_arn       = module.lambda_nr_ownership_ingest_participant_writer.lambda_arn,
    product_deduplicator_arn     = module.lambda_nr_ownership_ingest_product_deduplicator.lambda_arn,
    product_writer_arn           = module.lambda-nr-ownership-ingest-product-writer.lambda_arn,
    sr_deduplicator_arn          = module.lambda_nr_ownership_ingest_sr_deduplicator.lambda_arn,
    sr_writer_arn                = module.lambda-nr-ownership-ingest-sr-writer.lambda_arn,
    rules_writer_arn             = module.lambda_nr_ownership_ingest_rules_writer.lambda_arn,
    contributor_deduplicator_arn = module.lambda_nr_ownership_ingest_contributor_deduplicator.lambda_arn,
    contributor_writer_arn       = module.lambda_nr_ownership_ingest_contributor_writer.lambda_arn,
    finalizer_arn                = module.lambda_nr_ownership_ingest_finalizer.lambda_arn,

    bucket_name = data.aws_s3_bucket.s3_bucket.bucket,
  })

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.state_machine_name
    terraformed        = true
  }

  tracing_configuration {
    enabled = true
  }
}