module "neo4j_debian_13" {
  source = "git@github.com:theorchard/terraform-neo4j-cluster.git//debian?ref=1.1.0"

  environment             = var.environment
  service_name            = "${var.service_name}-debian-13"
  vpc_id                  = module.vpc_info_x8.vpc_id
  vpc_private_subnet_ids  = module.vpc_info_x8.default_private_subnet_ids
  data_volume_device_name = "/dev/sdb"
  data_volume_device_type = "gp3"
  data_volume_iops        = 12000
  data_volume_size        = 6000
  data_volume_throughput  = 1250
  # it can't go any faster than that due to instance type limitations
  ssh_keypair_name                  = "orchard_admin"
  route53_zone_id                   = var.route53_zone_id
  data_volume_delete_on_termination = true
  aws_instance_type                 = "x8g.8xlarge"
  user_data                         = module.chef_bootstrap_neo4j_debian_13.user_data_output

  ami_id           = data.aws_ami.debian_13_arm64.id
  desired_capacity = 3
  min_size         = 3
  max_size         = 3

  bolt_ingress_cidr_blocks = [
    "192.168.31.0/24",
    "192.168.32.0/24",
    "192.168.33.0/24",
    "192.168.40.0/22",
  ]
}

module "chef_bootstrap_neo4j_debian_13" {
  source = "git@github.com:theorchard/terraform-chef-bootstrap.git//?ref=4.0.1"

  chef_role                    = "qa_neo4j_debian_13"
  chef_environment             = var.environment
  aws_iam_role_id              = module.neo4j_debian_13.instance_iam_role_name_output
  aws_instance_name            = "${var.environment}-${var.service_name}-debian-13"
  ebs_data_mount_point         = "/var/lib/neo4j"
  block_device_filesystem_type = "xfs"
}

data "aws_ami" "debian_13_arm64" {
  most_recent = true

  owners = ["086679231553"]

  filter {
    name   = "name"
    values = ["debian-13-arm64-*"]
  }
}

resource "aws_security_group_rule" "allow_shared_jenkins_nodes_ssh_debian_13" {
  type      = "ingress"
  from_port = 22
  to_port   = 22
  protocol  = "TCP"
  prefix_list_ids = [
    data.aws_ec2_managed_prefix_list.shared_account_prefix_list.id,
    data.aws_ec2_managed_prefix_list.vpn_sme_internal_primary.id,
    data.aws_ec2_managed_prefix_list.jump-box-private.id,
  ]
  security_group_id = module.neo4j_debian_13.instance_security_group_id_output
}

resource "aws_security_group_rule" "allow_shared_jenkins_nodes_neo4j_debian_13" {
  type      = "ingress"
  from_port = 7687
  to_port   = 7687
  protocol  = "TCP"
  prefix_list_ids = [
    data.aws_ec2_managed_prefix_list.shared_account_prefix_list.id,
  ]
  security_group_id = module.neo4j_debian_13.instance_security_group_id_output
}

# The following two rules are temporary and will be removed once the migration is complete.
resource "aws_security_group_rule" "intra_asg_qa_debian13" {
  from_port                = 5000
  protocol                 = "TCP"
  to_port                  = 8000
  type                     = "ingress"
  security_group_id        = module.neo4j_debian_13.instance_security_group_id_output
  source_security_group_id = module.neo4j_5_debian_environment.instance_security_group_id_output
}

resource "aws_security_group_rule" "intra_asg_qa_neo4j_5" {
  from_port                = 5000
  protocol                 = "TCP"
  to_port                  = 8000
  type                     = "ingress"
  security_group_id        = module.neo4j_5_debian_environment.instance_security_group_id_output
  source_security_group_id = module.neo4j_debian_13.instance_security_group_id_output
}

resource "aws_iam_role_policy_attachment" "qa_neo4j_debian_assume_role_policy_deb13" {
  role       = module.neo4j_debian_13.instance_iam_role_name_output
  policy_arn = aws_iam_policy.assume_cross_account_neo4j_dns_update_role_policy.arn
}

resource "aws_iam_role_policy_attachment" "prod_kms_backup_policy_attachment_deb13" {
  role       = module.neo4j_debian_13.instance_iam_role_name_output
  policy_arn = data.aws_iam_policy.prod_neo4j_backup_kms_policy.arn
}

resource "aws_iam_role_policy_attachment" "prod_s3_backup_readonly_policy_attachment_deb13" {
  role       = module.neo4j_debian_13.instance_iam_role_name_output
  policy_arn = data.aws_iam_policy.prod_neo4j_backup_s3_readonly_policy.arn
}

resource "aws_iam_role_policy_attachment" "qa_restore_policy_attachment_deb13" {
  role       = module.neo4j_debian_13.instance_iam_role_name_output
  policy_arn = data.aws_iam_policy.secrets_manager_restore_policy.arn
}

resource "aws_security_group_rule" "bolt_ingress_prefix_lists_debian13" {
  type              = "ingress"
  from_port         = 7687
  to_port           = 7687
  protocol          = "TCP"
  security_group_id = module.neo4j_debian_13.instance_security_group_id_output
  prefix_list_ids = [
    for prefix_list in data.aws_ec2_managed_prefix_list.bolt_ingress_prefix_lists : prefix_list.id
  ]
  depends_on = [module.neo4j_debian_13]
}