module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}


# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-analytics-sr/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.0.2"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io."
}

module "analytics_sr_metadata_dynamodb_table" {
  source = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"

  env                    = var.environment
  table_name             = "analytics_sr_metadata"
  application_family     = var.application_family
  range_key_enabled      = true
  use_on_demand          = true
  hash_key               = var.hash_key
  range_key              = var.range_key
  range_type             = var.range_type
  attribute              = var.attributes
  global_secondary_index = var.secondary_indices
}

data "aws_iam_policy_document" "analytics_sr_metadata_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "*"
    ]
    actions = [
      "dynamodb:ListTables",
      "dynamodb:ListStreams"
    ]
  }

  statement {
    effect = "Allow"
    resources = [
      module.analytics_sr_metadata_dynamodb_table.aws_dynamodb_table_arn_with_sort_key,
      "arn:aws:dynamodb:us-east-1:437795906767:table/qa_analytics_sr_metadata/*"
    ]
    actions = [
      "dynamodb:DescribeStream",
      "dynamodb:DescribeTable",
      "dynamodb:GetItem",
      "dynamodb:GetRecords",
      "dynamodb:Query",
      "dynamodb:Scan",
      "dynamodb:BatchGetItem"
    ]
  }
}

resource "aws_iam_policy" "analytics_sr_metadata_policy" {
  name        = "Dynamo-${var.environment}_analytics_sr_metadata-RO"
  description = "Policy for ows-analytics sound recording dynamo table"
  policy      = data.aws_iam_policy_document.analytics_sr_metadata_policy_document.json
}

module "ows_analytics_sr_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.1"

  environment_name = var.environment
  service_name     = var.service_name
}

module "ows_analytics_sr_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.5.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  application_family                       = var.application_family
  service_name                             = var.service_name
  aws_region                               = var.region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 1024
  task_memory                              = 2048
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled                    = false
  health_check_grace_period_seconds        = 120
  health_check_healthy_threshold           = 2
  container_start_period_seconds           = 120

  qa_https_listener_allow_cidr_blocks = [
    "192.168.31.0/24",
    "192.168.32.0/24",
    "192.168.33.0/24",
    "192.168.40.0/22",
    "10.30.0.0/22",
    "10.40.0.0/22",
    "10.110.0.0/24",
    "10.110.1.0/24",
  ]

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/Dynamo-qa-mobile_metadata-Full",
    "arn:aws:iam::437795906767:policy/Dynamo-qa-bff-mobile-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-qa-mobile_metadata-RW",
    # May use bff-mobile or ows-analytics
    module.ows_analytics_sr_owsrequest.policy_arn_output,
    "arn:aws:iam::437795906767:policy/Dynamo-qa_analytics_metadata-RO",
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      ANALYTICS_METADATA_TABLE = "qa_analytics_metadata"
    },
    {
      AWS_DEFAULT_REGION = "us-east-1"
    },
    {
      DYNAMO_TABLE = "qa-mobile_metadata"
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      SLOW_DYNAMO_TIME = "0.1"
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    }
  ]
}

module "elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"
  # checkov:skip=CKV_AWS_30:Handle checkov findings Ensure all data stored in the Elasticache Replication Group is securely encrypted at transit
  # checkov:skip=CKV_AWS_31:Handle checkov findings Ensure all data stored in the Elasticache Replication Group is securely encrypted at transit and has auth token
  # checkov:skip=CKV2_AWS_50:Handle checkov findings Ensure AWS ElastiCache Redis cluster with Multi-AZ Automatic Failover feature set to enabled

  providers = {
    aws.dns = aws.networking
  }

  environment                        = var.environment
  application_family                 = var.application_family
  service_name                       = var.service_name
  cache_engine                       = "redis"
  cache_subnet_group_name            = "prod-vpc-orchard-subnet"
  cache_node_type                    = "cache.t4g.micro"
  cache_node_count                   = 1
  cache_parameter_group_name         = "default.redis5.0"
  vpc_id                             = module.vpc_info.vpc_id
  route53_zone_id                    = data.aws_route53_zone.route53_zone.zone_id
  auto_minor_version_upgrade_enabled = false
  cache_transit_encryption_enabled   = false
}

# Secrets manager entry for analytics vanity FQDN
resource "aws_secretsmanager_secret" "ows_analytics_sr_cache_fqdn_secret" {
  name        = "${var.environment}/${var.service_name}/REDIS_HOST"
  description = "FQDN for ows-analytics redis cache"
}
resource "aws_secretsmanager_secret_version" "ows_analytics_sr_cache_fqdn_secret" {
  secret_id     = aws_secretsmanager_secret.ows_analytics_sr_cache_fqdn_secret.id
  secret_string = module.elasticache.redis_primary_endpoint_address
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.10.7"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}