module "ows_analytics_build_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.3.0"

  secrets = [
    "${var.environment}/${var.service_name}/SNOWFLAKE_PASSWORD",
    "${var.environment}/${var.service_name}/SNOWFLAKE_APOLLO_DATABASE",
  ]
  action_types = ["read"]
}

resource "aws_iam_policy" "ows_analytics_build_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-integration-test-policy"
  policy = module.ows_analytics_build_secrets_manager_policy.policy.json
}

data "aws_iam_role" "pipeline_agent_role" {
  name = "prod-jenkins-aws-pipeline-agent"
}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        data.aws_iam_role.pipeline_agent_role.arn,
      ]
    }
  }
}

data "aws_iam_role" "scheduler_agent_role" {
  name = "prod-jenkins-aws-task-agent"
}

data "aws_iam_policy_document" "scheduler_jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"
      identifiers = [
        data.aws_iam_role.scheduler_agent_role.arn,
      ]
    }
  }
}

resource "aws_iam_role" "ows_analytics_build_role" {
  name = "${var.environment}-${var.service_name}-integration-test-role"

  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "ows_analytics_build_role_policy_attachment" {
  role       = aws_iam_role.ows_analytics_build_role.name
  policy_arn = aws_iam_policy.ows_analytics_build_secrets_manager_policy.arn
}

module "ows_analytics_warmup_cache_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.3.0"

  secrets = [
    "${var.environment}/datadog/DD_APP_KEY",
    "${var.environment}/datadog/DD_API_KEY",
  ]
  action_types = ["read"]
}

resource "aws_iam_policy" "ows_analytics_warmup_cache_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-warmup-cache-policy"
  policy = module.ows_analytics_warmup_cache_secrets_manager_policy.policy.json
}

resource  "aws_iam_role" "ows_analytics_warmup_cache_role"  {
  name = "${var.environment}-${var.service_name}-warmup-cache-role"

  assume_role_policy = data.aws_iam_policy_document.scheduler_jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "ows_analytics_warmup_cache_role_policy_attachment" {
  role       = aws_iam_role.ows_analytics_warmup_cache_role.name
  policy_arn = aws_iam_policy.ows_analytics_warmup_cache_secrets_manager_policy.arn
}