module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-analytics/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.0.2"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io."
}

module "analytics_metadata_dynamodb_table" {
  source = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"

  env                    = var.environment
  application_family     = var.application_family
  table_name             = "analytics_metadata"
  range_key_enabled      = true
  read_capacity          = var.read_capacity
  hash_key               = var.hash_key
  range_key              = var.range_key
  range_type             = var.range_type
  attribute              = var.attributes
  global_secondary_index = var.secondary_indices
}

module "ows_legacy_analytics_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.1"

  environment_name = var.environment
  service_name     = "ows-legacy-analytics"
}

module "ows_analytics_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.1"

  environment_name = var.environment
  service_name     = var.service_name
}

data "aws_iam_policy_document" "additional_secrets_policy" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:ListSecretVersionIds",
      "secretsmanager:GetSecretValue",
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:DescribeSecret",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/python-orchard-features/*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/python-orchard-features/"
    ]
  }
}

resource "aws_iam_policy" "additional_secrets_policy" {
  name   = "SecretsManager-${var.environment}-ows-analytics-additional-secrets-policy"
  policy = data.aws_iam_policy_document.additional_secrets_policy.json
}

module "legacy_elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"
  # checkov:skip=CKV_AWS_30:Handle checkov findings Ensure all data stored in the Elasticache Replication Group is securely encrypted at transit
  # checkov:skip=CKV_AWS_31:Handle checkov findings Ensure all data stored in the Elasticache Replication Group is securely encrypted at transit and has auth token
  # checkov:skip=CKV2_AWS_50:Ensure AWS ElastiCache Redis cluster with Multi-AZ Automatic Failover feature set to enabled

  providers = {
    aws.dns = aws.networking
  }

  environment                        = var.environment
  application_family                 = var.application_family
  service_name                       = "${var.service_name}-legacy"
  cache_engine                       = "redis"
  redis_engine_version               = "6.2"
  cache_subnet_group_name            = "prod-vpc-orchard-subnet"
  cache_node_count                   = 1
  cache_node_type                    = "cache.t4g.micro"
  cache_parameter_group_name         = "default.redis5.0"
  vpc_id                             = module.vpc_info.vpc_id
  route53_zone_id                    = data.aws_route53_zone.route53_zone.zone_id
  cache_transit_encryption_enabled   = false
  auto_minor_version_upgrade_enabled = false
  additional_cidr_blocks_enabled     = true
  additional_cidr_blocks = [
    "10.40.0.0/22",
    "10.30.0.0/22",
    "192.168.31.0/24",
    "192.168.32.0/24",
    "192.168.33.0/24",
    "192.168.40.0/22",
  ]
}
resource "aws_secretsmanager_secret" "legacy_fqdn_cache_secret" {
  name        = "${var.environment}/ows-legacy-analytics/REDIS_HOST"
  description = "FQDN for ows-legacy-analytics redis cache"
}
resource "aws_secretsmanager_secret_version" "legacy_fqdn_cache_secret" {
  secret_id     = aws_secretsmanager_secret.legacy_fqdn_cache_secret.id
  secret_string = module.legacy_elasticache.redis_primary_endpoint_address
}

# Old ows-analytics, now known as ows-legacy-analytics
module "ows_legacy_analytics_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.5.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  application_family                       = var.application_family
  service_name                             = "ows-legacy-analytics"
  aws_region                               = var.region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 1024
  task_memory                              = 2048
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled                    = false
  health_check_grace_period_seconds        = 300
  container_start_period_seconds           = 300
  blocking_waf_enabled                     = false

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/Dynamo-qa-ows-analytics-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-qa-ows-legacy-analytics-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-streams_vendor_totals-RW",
    "arn:aws:iam::437795906767:policy/Dynamo-streams_track_totals-RW",
    "arn:aws:iam::437795906767:policy/Dynamo-stream-wildcard-RW",
    "arn:aws:iam::437795906767:policy/dev-aggregate-analytics",
    "arn:aws:iam::437795906767:policy/S3-nickelback_qa-ows-analytics-RO",
    "arn:aws:iam::437795906767:policy/Dynamo-ows-analytics-qa-active-table-RO",
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      DATADOG_ENV = "${var.environment}-ows-legacy-analytics"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      SNOWFLAKE_INSECURE_MODE = "True"
    }
  ]
  secrets = [
    { APPLE_MUSIC_PRIVATE_KEY = "${var.environment}/ows-legacy-analytics/APPLE_MUSIC_PRIVATE_KEY" }
  ]
}

module "ows_analytics_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.5.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  application_family                       = var.application_family
  service_name                             = var.service_name
  aws_region                               = var.region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 2048
  task_memory                              = 4096
  maximum_capacity                         = 2
  minimum_capacity                         = 2
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled                    = false
  health_check_grace_period_seconds        = 120
  health_check_healthy_threshold           = 2
  container_start_period_seconds           = 120
  blocking_waf_enabled                     = false

  qa_https_listener_allow_cidr_blocks = [
    "192.168.31.0/24",
    "192.168.32.0/24",
    "192.168.33.0/24",
    "192.168.40.0/22",
    "10.30.0.0/22",
    "10.40.0.0/22",
    "10.110.0.0/24",
    "10.110.1.0/24",
  ]

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/Dynamo-qa-mobile_metadata-Full",
    "arn:aws:iam::437795906767:policy/Dynamo-qa-bff-mobile-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-qa-mobile_metadata-RW",
    # May use bff-mobile or ows-analytics
    "arn:aws:iam::437795906767:policy/Dynamo-qa-ows-analytics-owsrequest",
    "arn:aws:iam::437795906767:policy/SecretsManager-qa-ows-analytics-policy",
    "arn:aws:iam::437795906767:policy/Dynamo-qa_analytics_metadata-RO",
    aws_iam_policy.additional_secrets_policy.arn,
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      ANALYTICS_METADATA_TABLE = "qa_analytics_metadata"
    },
    {
      AWS_DEFAULT_REGION = "us-east-1"
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      DYNAMO_TABLE = "qa-mobile_metadata"
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      SLOW_DYNAMO_TIME = "0.1"
    },
    {
      SNOWFLAKE_OWS_PODCAST_DB_SCHEMA = var.snowflake_ows_podcast_db_schema
    },
    {
      SPLITIO_USE_PREFORKED_INITIALIZATION = var.splitio_preforked
    }
  ]
}

# Create QA ows-analytics integration tests user
resource "aws_iam_user" "integration_tests_user" {
  name = "${var.environment}-${var.service_name}-integration-tests"
  tags = {
    terraformed = true
    role        = "service-user"
  }
}

# Allow integration tests user to fetch secrets
resource "aws_iam_user_policy_attachment" "integration_tests_secrets_manager_policy_attachment" {
  user       = aws_iam_user.integration_tests_user.name
  policy_arn = "arn:aws:iam::437795906767:policy/SecretsManager-qa-ows-analytics-policy"
}

# Allow integration tests user to fetch additional secrets
resource "aws_iam_user_policy_attachment" "integration_tests_additional_secrets_manager_policy_attachment" {
  user       = aws_iam_user.integration_tests_user.name
  policy_arn = aws_iam_policy.additional_secrets_policy.arn
}

module "elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"
  # checkov:skip=CKV_AWS_30:Handle checkov findings Ensure all data stored in the Elasticache Replication Group is securely encrypted at transit
  # checkov:skip=CKV_AWS_31:Handle checkov findings Ensure all data stored in the Elasticache Replication Group is securely encrypted at transit and has auth token
  # checkov:skip=CKV2_AWS_50:Ensure AWS ElastiCache Redis cluster with Multi-AZ Automatic Failover feature set to enabled

  providers = {
    aws.dns = aws.networking
  }

  environment                        = var.environment
  application_family                 = var.application_family
  service_name                       = var.service_name
  redis_engine_version               = "5.0.6"
  cache_engine                       = "redis"
  cache_subnet_group_name            = "prod-vpc-orchard-subnet"
  cache_node_count                   = 1
  cache_transit_encryption_enabled   = false
  cache_node_type                    = "cache.t4g.micro"
  cache_parameter_group_name         = "default.redis5.0"
  vpc_id                             = module.vpc_info.vpc_id
  route53_zone_id                    = data.aws_route53_zone.route53_zone.zone_id
  auto_minor_version_upgrade_enabled = false
}
resource "aws_secretsmanager_secret" "ows_analytics_cache_fqdn_secret" {
  name        = "${var.environment}/${var.service_name}/REDIS_HOST"
  description = "FQDN for ows-analytics redis cache"
}

resource "aws_secretsmanager_secret_version" "ows_analytics_cache_fqdn_secret" {
  secret_id     = aws_secretsmanager_secret.ows_analytics_cache_fqdn_secret.id
  secret_string = module.elasticache.redis_primary_endpoint_address
}

module "fargate_ows_legacy_analytics_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.10.7"
  environment                       = var.environment
  application_family                = var.application_family
  environment_type                  = "fargate"
  service_name                      = "ows-legacy-analytics"
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.10.7"
  environment                       = var.environment
  application_family                = var.application_family
  environment_type                  = "fargate"
  service_name                      = var.service_name
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}

module "ows_analytics_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_legacy_secret_names)

  environment                    = var.environment
  service_name                   = "ows-legacy-analytics"
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}