module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-assets/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

locals {
  match_audio_dynamodb_table_name = "${var.environment}_content_review_match_audio_match"
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy" "pre_existing_policies" {
  for_each = toset(local.pre_existing_policy_names)
  name     = each.value
}

data "aws_dynamodb_table" "match_audio_dynamodb_table" {
  name = local.match_audio_dynamodb_table_name
}

data "aws_iam_policy_document" "match_audio_dynamodb_table_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      data.aws_dynamodb_table.match_audio_dynamodb_table.arn
    ]
    actions = [
      "dynamodb:BatchGetItem"
    ]
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

resource "aws_iam_policy" "match_audio_dynamodb_table_policy" {
  name        = "${var.environment}-${var.service_name}-match-audio-dynamodb-table-policy"
  description = "Give ows-assets read access to the DynamoDB table where audio matching results are stored."
  policy      = data.aws_iam_policy_document.match_audio_dynamodb_table_policy_document.json
}

module "ows_assets_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=5.0.0"

  application_family = var.application_family
  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  teams              = [var.environment]
}

module "ows_assets_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.service_name

}

module "ows_assets_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.3"

  providers = {
    aws.dns = aws.networking
  }

  application_family                       = var.application_family
  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 1024
  task_memory                              = 2048
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  blocking_waf_enabled                     = false
  # waf_type                                = "count_only"
  autoscaling_memory_policy_enabled = true
  scaling_memory_target_value       = 80

  iam_managed_policy_attachments = concat(
    [module.ows_assets_owsrequest.policy_arn_output],
    [data.aws_iam_policy.cloudfront_invalidation_policy.arn],
    [for policy in data.aws_iam_policy.pre_existing_policies : policy.arn],
    [aws_iam_policy.match_audio_dynamodb_table_policy.arn],
    [aws_iam_policy.raw_assets_write_policy.arn],
  )

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  https_listener_allow_security_group_ids = flatten([
    [for service in module.service_info : service.security_groups],
  ])

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_PATCH_MODULES = "requests:true"
    },
    {
      DD_APM_ANALYZED_SPANS = "flask|flask.request=1,requests|requests.request=1,aws.dynamodb|dynamodb.command=1,aws.secretsmanager|secretsmanager.command=1"
    },
    {
      WOWZA_PATH_PREFIX = var.WOWZA_PATH_PREFIX
    },
    {
      IAM_ROLE = aws_iam_role.service_role.arn
    },
    {
      MANAGE_ASSET_URL = var.MANAGE_ASSET_URL
    },
    {
      REDIS_HOST = module.elasticache.redis_primary_endpoint_address
    },
    {
      REDIS_PORT = var.REDIS_PORT
    },
    {
      SENTRY_DSN = module.ows_assets_sentry_project.sentry_key_dsn_public_output
    },
    {
      SERVER_LOCATION_AVL = var.SERVER_LOCATION_AVL
    },
    {
      STREAM_URL = var.STREAM_URL
    },
    {
      STS_TOKEN_DURATION = var.STS_TOKEN_DURATION
    },
    {
      WOWZA_PATH_PREFIX_V2 = var.WOWZA_PATH_PREFIX_V2
    },
    {
      WOWZA_URL = var.WOWZA_URL
    },
    {
      WOWZA_URL_V2 = var.WOWZA_URL_V2
    },
    {
      MATCH_AUDIO_DYNAMODB_TABLE_NAME = local.match_audio_dynamodb_table_name
    },
    {
      UWSGI_WORKERS = var.UWSGI_WORKERS
    },
    {
      UWSGI_CHEAPER_RSS_LIMIT_SOFT = tostring(floor(pow(10, 9) * var.UWSGI_CHEAPER_RSS_LIMIT_SOFT_GB))
    },
    {
      IS_REDIS_SSL_ENABLED = "true"
    },
    {
      RDS_DB_HOST = module.ows_assets_rds.rds_cluster_endpoint
    },
    {
      RDS_DB_NAME = module.ows_assets_rds.rds_cluster_database_name
    },
    {
      RDS_DB_USER = var.rds_db_user
    },
    {
      RDS_DB_CONNECTION_CHARSET = var.rds_db_connection_charset
    },
    {
      AR_DB_HOST = var.ar_db_host
    },
    {
      AR_DB_NAME = var.ar_db_name
    },
    {
      AR_DB_USER = var.ar_db_user
    },
    {
      AR_DB_CONNECTION_CHARSET = var.ar_db_connection_charset
    },
  ]
}

module "ows_assets_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=8.0.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                               = var.environment
  service_name                              = var.service_name
  application_family                        = var.application_family
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_engine_version                        = "8.0.mysql_aurora.3.10.3"
  rds_cluster_instance_class                = "db.r6g.large"
  rds_cluster_instance_count                = "1"
  rds_master_username                       = "dummy"
  rds_master_password                       = "dummy"
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  rds_db_cluster_parameter_group_name       = "aurora-mysql80sync"
  rds_performance_insights_enabled          = true
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  enabled_cloudwatch_logs_exports           = ["audit", "error", "general"]
  custom_kms_key_enabled                    = false
  vpc_id                                    = module.vpc_info.vpc_id
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.1"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

module "elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=4.0.2"

  providers = {
    aws.dns = aws.networking
  }

  environment             = var.environment
  service_name            = "${var.service_name}-cache"
  application_family      = var.application_family
  cache_engine            = "redis"
  redis_engine_version    = "7.1"
  cache_node_type         = "cache.t4g.micro"
  cache_subnet_group_name = "${var.environment}-elasticache-subnet-group"
  cache_node_count        = 1
  vpc_id                  = module.vpc_info.vpc_id
}

module "raw_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.7"

  env                 = var.environment
  bucket_name         = "orcd-raw-assets"
  application_family  = var.application_family
  acceleration_status = "Enabled"

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = ["https://*.theorchard.io"]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    },
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = ["https://*.qaorch.com"]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    },
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = ["https://workstation.qaawal.com"]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    },
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = ["http://localhost:*"]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    },
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = ["https://*.devorch.com"]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    }
  ]
}

module "service_info" {
  for_each     = toset(local.downstream_services)
  source       = "git@github.com:theorchard/terraform-service-info.git//?ref=1.1.0"
  service_name = each.value
  environment  = var.environment
}