module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations.
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-collaborator/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

module "ows_service_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.service_name
}

module "ows_collaborator" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=7.0.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                         = var.environment
  application_family                  = var.application_family
  rds_engine_version                  = "8.0"
  service_name                        = "ows-collaborator"
  rds_cluster_instance_count          = "1"
  rds_db_subnet_group_name            = "prod-orchard-private-subnet-group"
  rds_availability_zones              = ["us-east-1a", "us-east-1d"]
  rds_master_username                 = "dummy"
  rds_master_password                 = "dummy"
  rds_performance_insights_enabled    = false
  rds_cluster_instance_class          = "db.t4g.medium"
  rds_db_cluster_parameter_group_name = "aurora-mysql80sync"
  enabled_cloudwatch_logs_exports     = ["audit", "error", "general"]

  rds_cluster_instance_parameters = [
    {
      name         = "thread_stack"
      value        = "1048576"
      apply_method = "pending-reboot"
    }
  ]

  custom_kms_key_enabled = false

  vpc_id = module.vpc_info.vpc_id
}

data "aws_iam_policy" "ses_send_only" {
  name = "SES-SendOnly"
}

data "aws_iam_policy" "report_trigger_queue" {
  name = "SQS-${var.environment}-collaborator-report-trigger-minimal-policy"
}

data "aws_iam_policy" "auto_report_run_lambda_invoke" {
  name = "${var.environment}-lambda-collaborator-auto-report-run-invoke-policy"
}

# Setup fargate environment.
module "ows_collaborator_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  service_name                             = var.service_name
  application_family                       = var.application_family
  aws_region                               = var.aws_region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 1024
  task_memory                              = 2048
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  health_check_path                        = "/hello/"
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  blocking_waf_enabled                     = false

  iam_managed_policy_attachments = [
    module.ows_service_owsrequest.policy_arn_output,
    module.elasticsearch_collaborator_audit_log.aws_iam_default_rw_access_policy,
    data.aws_iam_policy.report_trigger_queue.arn,
    data.aws_iam_policy.ses_send_only.arn,
    data.aws_iam_policy.auto_report_run_lambda_invoke.arn,
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      DD_TRACE_HEADER_TAGS = "x-trace-id:http.x_trace_id"
    },
    {
      LOGGER_DSN = "https://qa-fluentd-applications.theorchard.io:8888/application"
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_WRITER_WAREHOUSE = var.snowflake_writer_warehouse
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_SCHEMA_FACTS = var.snowflake_schema_facts
    },
    {
      SNOWFLAKE_SCHEMA_ROYALTY_ACCOUNTING = var.snowflake_schema_royalty_accounting
    },
    {
      SNOWFLAKE_SCHEMA_OWS_COLLABORATOR = var.snowflake_schema_ows_collaborator
    },
    {
      SPLITIO_USE_PREFORKED_INITIALIZATION = var.splitio_preforked
    },
    {
      SENTRY_DSN = module.ows_collaborator_sentry.sentry_key_dsn_public_output
    },
    {
      ENABLE_PROFILER = "true"
    },
    {
      AUDIT_LOG_ES = var.audit_log_host
    },
    {
      AUDIT_LOG_USER = var.audit_log_user
    },
    {
      TRANSFERWISE_CLIENT_ID = var.transferwise_client_id
    },
    {
      COLLAB_DB_USER = var.collab_db_user
    },
    {
      COLLAB_DB_HOST = var.collab_db_host
    },
    {
      COLLAB_DB_DBNAME = var.collab_db_dbname
    },
  ]

  secrets = [
    {
      TRANSFERWISE_CLIENT_SECRET = "${var.environment}/${var.service_name}/TRANSFERWISE_CLIENT_SECRET"
    },
    {
      SNOWFLAKE_KEY_PASSPHRASE = "${var.environment}/${var.service_name}/SNOWFLAKE_KEY_PASSPHRASE"
    },
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
    {
      AUDIT_LOG_PASS = "${var.environment}/${var.service_name}/AUDIT_LOG_PASS"
    },
    {
      COLLAB_DB_PASS = "${var.environment}/${var.service_name}/COLLAB_DB_PASS"
    },
    {
      DD_API_KEY = "${var.environment}/datadog/DD_API_KEY"
    },
    {
      DD_APP_KEY = "${var.environment}/datadog/DD_APP_KEY"
    },
  ]
}

# # Setup datadog dashboards.
module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.16.1"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  service_4xx_monitor_enabled       = false
  application_family                = var.application_family
  notification_endpoints            = ""
  escalation_notification_endpoints = ""
}

module "s3_ows_collaborator_reports" {
  source             = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.1"
  env                = var.environment
  bucket_name        = "${var.service_name}-reports"
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

# Audit logging
# Todo: temporarily move to KDH application family until we finish replacing it with OS instance.
module "elasticsearch_collaborator_audit_log" {
  source = "git@github.com:theorchard/terraform-elasticsearch.git//?ref=5.0.0"

  providers = {
    aws.dns = aws.networking
  }

  env                                                      = var.environment
  application_family                                       = var.kdh_application_family
  aws_es_domain_name                                       = "${var.service_name}-log"
  aws_es_instance_type                                     = "t3.small.elasticsearch"
  aws_es_instance_count                                    = 1
  aws_es_disk_size                                         = 25
  zone_awareness_enabled                                   = false
  encrypt_at_rest_enabled                                  = true
  node_to_node_encryption_option                           = true
  advanced_security_options_enabled                        = true
  advanced_security_options_internal_user_database_enabled = true

  vpc_id     = module.vpc_info.vpc_id
  subnet_ids = [module.vpc_info.default_private_subnet_ids[0]]

  qa_https_allowed_custom_cidr_blocks = [
    "10.40.0.0/22",
    "192.168.40.0/22",
    "192.168.32.0/24",
  ]
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

module "ows_collaborator_sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
  teams              = [var.environment]
}