module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}
data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-dmp-workflows/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.0.2"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = var.route53_hosted_zone
}

module "ows_dmp_workflows_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.1"

  environment_name = var.environment
  service_name     = var.service_name
}

module "ows_dmp_workflows_managed_airflow_environment" {
  count = var.airflow_enabled ? 1 : 0

  source = "git@github.com:theorchard/terraform-airflow.git//?ref=3.0.1"

  providers = {
    aws.dns = aws.networking
  }

  environment               = var.environment
  service_name              = var.service_name
  application_family        = var.application_family
  airflow_version           = var.airflow_version
  airflow_environment_class = var.environment_class
  airflow_log_enabled       = true
  airflow_log_level         = "INFO"
  bucket_name               = module.ows_dmp_workflows_s3_bucket.s3_bucket_name_output
  airflow_create_iam_policies_for_roles_web_auth = [
    "Admin",
  ]
  airflow_configuration_options = {
    "core.default_task_retries"             = 0
    "core.parallelism"                      = 16
    "celery.worker_autoscale"               = "8,2"
    "custom.ows_env"                        = var.environment
    "custom.snowflake_account"              = var.snowflake_account
    "custom.snowflake_database"             = var.snowflake_database
    "custom.snowflake_schema"               = var.snowflake_schema
    "custom.snowflake_warehouse"            = var.snowflake_warehouse
    "custom.snowflake_role"                 = var.snowflake_role
    "custom.snowflake_user"                 = var.snowflake_user
    "custom.snowflake_password_secret_name" = local.snowflake_password_secret_name
  }
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids
  https_listener_allow_prefix_lists = [
    "vpn-ny-users",
    module.vpc_info.private_subnet_prefix_list_name,
  ]

  airflow_external_policies_to_attach = [
    aws_iam_policy.ows_dmp_workflows_secrets_manager_policy.name,
    module.ows_dmp_workflows_owsrequest.policy_name_output,
    data.aws_iam_policy.ows_machine_to_machine_policy.name,
  ]
}