module "audience_campaign_assets_s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.5"

  bucket_name        = "audience-campaign-assets"
  env                = var.environment
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
  acceleration_status = "Enabled"

  bucket_policy_overrides = [
    data.aws_iam_policy_document.cloudfront_s3_policy_document.json,
  ]

  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 7
    }
  ]

  lifecycle_rules_abort_incomplete_multipart_upload_days = [
    {
      prefix  = ""
      enabled = true
      days    = 1
    }
  ]
}

data "aws_iam_policy_document" "campaign_assets_s3_write_only_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:PutObject",
      "s3:CreateMultipartUpload",
      "s3:UploadPart",
      "s3:AbortMultipartUpload",
      "s3:CompleteMultipartUpload",
    ]

    resources = [
      "${module.audience_campaign_assets_s3_bucket.s3_bucket_arn_output}/*",
    ]
  }
}

resource "aws_iam_policy" "campaign_assets_s3_write_only_policy" {
  name        = "S3-${module.audience_campaign_assets_s3_bucket.s3_bucket_name_output}-WO"
  description = "Write-only access to ${module.audience_campaign_assets_s3_bucket.s3_bucket_name_output} bucket"
  policy      = data.aws_iam_policy_document.campaign_assets_s3_write_only_policy_document.json
}