module "ows_lyrics_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.4.0"

  secrets      = ["${var.Environment}/${var.service_name}/AUTOMATION_QA_DB_PASS"]
  action_types = ["read"]

  depends_on = [
    module.secrets,
  ]
}

resource "aws_iam_policy" "ows_lyrics_secrets_manager_policy" {
  name   = "SecretsManager-${var.Environment}-${var.service_name}-integration-test-policy"
  policy = module.ows_lyrics_secrets_manager_policy.policy.json
}

data "aws_iam_role" "pipeline_agent_role" {
  name = "prod-jenkins-aws-pipeline-agent"
}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        data.aws_iam_role.pipeline_agent_role.arn,
      ]
    }
  }
}

resource "aws_iam_role" "ows_lyrics_role" {
  name = "${var.Environment}-${var.service_name}-integration-test-role"

  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "ows_lyrics_role_policy_attachment" {
  role       = aws_iam_role.ows_lyrics_role.name
  policy_arn = aws_iam_policy.ows_lyrics_secrets_manager_policy.arn
}

module "ows_pricing_owsrequest" {
  source             = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"
  policy_description = "Dynamo-${var.Environment}-${var.service_name}-owsrequest"
  environment_name   = var.Environment
  service_name       = var.service_name
}

# Attach Dynamo qa-ows-request-authorization policy to integration test role.
resource "aws_iam_role_policy_attachment" "qa-ows-request-authorization-dynamo-policy_attachment" {
  role       = aws_iam_role.ows_lyrics_role.name
  policy_arn = module.ows_pricing_owsrequest.policy_arn_output
}