module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.Environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-lyrics/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.Environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_s3_bucket" "logging_bucket_waf" {
  bucket = "aws-waf-logs-prod-tf-orcd-bucket"
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.Environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "ows_lyrics_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.7.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.Environment
  service_name                             = var.service_name
  application_family                       = var.application_family
  aws_region                               = var.aws_region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 512
  task_memory                              = 1024
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  custom_waf_arn                           = module.ows_lyrics_waf.waf_blocking_arn_output
  # overriding here to add in the graphql_switchboard_vpc (10.110.0.0/16) private subnets
  qa_https_listener_allow_cidr_blocks = [
    "192.168.31.0/24",
    "192.168.32.0/24",
    "192.168.33.0/24",
    "192.168.40.0/22",
    "10.30.0.0/22",
    "10.40.0.0/22",
    "10.110.0.0/24",
    "10.110.1.0/24",
  ]

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/Dynamo-qa-ows-lyrics-owsrequest"
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.Environment
    },
    {
      LOGGER_DSN = "https://qa-fluentd-applications.theorchard.io:8888/application"
    },
    {
      DATADOG_ENV = "${var.Environment}-${var.service_name}"
    },
    {
      AR_MYSQL_DATABASE = "art_relations"
    },
    {
      AR_MYSQL_HOST = "qa.db.qaorch.com"
    },
    {
      AR_MYSQL_PORT = "3306"
    },
    {
      AR_MYSQL_USER = "ows_lyrics"
    },
    {
      DD_APM_ANALYZED_SPANS = "flask|flask.request=1,requests|requests.request=1"
    }
  ]
  secrets = [
    {
      SENTRY_DSN = "${var.Environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      AR_MYSQL_PASSWORD = "${var.Environment}/${var.service_name}/AR_MYSQL_PASSWORD"
    }
  ]
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                       = var.Environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  service_4xx_monitor_enabled       = true
  service_4xx_monitor_silenced      = true
  service_5xx_monitor_silenced      = true
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}

# Custom WAF that allows larger query strings until we refactor the code
module "ows_lyrics_waf" {
  source            = "git@github.com:theorchard/terraform-aws-waf.git//?ref=2.0.1"
  environment       = var.Environment
  service_name      = var.service_name
  aws_region        = var.aws_region
  count_waf_enabled = false
  block_waf_enabled = true
  excluded_rules = [
    "NoUserAgent_HEADER",
    "SizeRestrictions_BODY",
    "SizeRestrictions_QUERYSTRING",
    "CrossSiteScripting_BODY",
  ]

  logging_config_default_destination = data.aws_s3_bucket.logging_bucket_waf.arn
}

# Create IAM user for jenkins qa-ows-lyrics integration test"
resource "aws_iam_user" "qa-ows-lyrics-integration-test-user" {
  name = "qa-${var.service_name}-integration-tests"
  tags = {
    application_family = var.application_family
    environment        = var.Environment
    role               = "service-user"
    service_name       = var.service_name
    terraformed        = true
  }
}

# Attach Dynamo qa-ows-request-authorization policy to iam user.
resource "aws_iam_user_policy_attachment" "qa-ows-request-authorization-dynamo-policy" {
  user       = aws_iam_user.qa-ows-lyrics-integration-test-user.name
  policy_arn = "arn:aws:iam::437795906767:policy/Dynamo-qa-ows-lyrics-owsrequest"
}