provider "aws" {
  region = var.aws_region
}

data "aws_caller_identity" "current" {}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-moneyhub/integration-test/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

# Username and Password Secrets for Auth0 Moneyhub Test User.
resource "aws_secretsmanager_secret" "auth0_test_user" {
  name = "${var.environment}/${var.service_name}/MONEYHUB_TEST_USER"
  tags = local.tags
}

resource "aws_secretsmanager_secret" "auth0_test_user_password" {
  name = "${var.environment}/${var.service_name}/MONEYHUB_TEST_USER_PASSWORD"
  tags = local.tags
}

# Auth0 secrets for QA/Test app used by the test user to create a token.
resource "aws_secretsmanager_secret" "auth0_moneyhub_app_client_id" {
  name = "${var.environment}/${var.service_name}/MONEYHUB_APP_CLIENT_ID"
  tags = local.tags
}

resource "aws_secretsmanager_secret" "auth0_moneyhub_app_client_secret" {
  name = "${var.environment}/${var.service_name}/MONEYHUB_APP_CLIENT_SECRET"
  tags = local.tags
}

data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [
      aws_secretsmanager_secret.auth0_test_user.arn,
      aws_secretsmanager_secret.auth0_test_user_password.arn,
      aws_secretsmanager_secret.auth0_moneyhub_app_client_id.arn,
      aws_secretsmanager_secret.auth0_moneyhub_app_client_secret.arn
    ]
  }

  statement {
    effect    = "Allow"
    actions   = [ 
      "ecr:GetDownloadUrlForLayer", 
      "ecr:BatchGetImage",
      "ecr:BatchCheckLayerAvailability"
    ]
    resources = [
      "arn:aws:ecr:${var.aws_region}:${data.aws_caller_identity.current.account_id}:repository/ows-moneyhub",
      "arn:aws:ecr:${var.aws_region}:${data.aws_caller_identity.current.account_id}:repository/royalties-liquibase-runner",
    ]
  }

  statement {
    effect    = "Allow"
    actions   = [ 
      "ecr:GetAuthorizationToken"
    ]
    resources = [
      "*",
    ]
  }
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:user/cucumber-tests",
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# SecretManager Access Policy
resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretManager-moneyhub-qa-refresh-access-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

# Jenkins agents will assume this role in order to access SecretManager
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-moneyhub-integration-test-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach SecretManager access policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "moneyhub_integration_secret_manager_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.secrets_manager_policy.arn
}