module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations.
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-product-physical/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

module "secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each           = toset(var.secrets_manager_secret_names)
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

# Setup fargate environment.
module "ows_product_physical_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  application_family                       = var.application_family
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 512
  task_memory                              = 1024
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  health_check_path                        = "/hello"
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  splitio_enabled                          = true

  # overriding here to add in the graphql_switchboard_vpc (10.110.0.0/16) private subnets
  qa_https_listener_allow_cidr_blocks = [
    "192.168.31.0/24",
    "192.168.32.0/24",
    "192.168.33.0/24",
    "192.168.40.0/22",
    "10.30.0.0/22",
    "10.40.0.0/22",
    "10.110.0.0/24",
    "10.110.1.0/24",
  ]

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/Dynamo-qa-ows-product-physical-owsrequest",
    "arn:aws:iam::437795906767:policy/SQS-qa-cloudsearch-etl-releases-update-q-RW",
    "arn:aws:iam::437795906767:policy/SQS-qa-upc_repository-minimal-policy",
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      LOGGER_DSN = "${var.environment}/${var.service_name}/LOGGER_DSN"
    },
    {
      MYSQL_PASSWORD = "${var.environment}/${var.service_name}/MYSQL_PASSWORD"
    },
    {
      SNOWFLAKE_PASSWORD = "${var.environment}/${var.service_name}/SNOWFLAKE_PASSWORD"
    },
    {
      MYSQL_DELIVERY_PASSWORD = "${var.environment}/${var.service_name}/MYSQL_DELIVERY_PASSWORD"
    },
    {
      SPLITIO_API_KEY = "${var.environment}/split/API_KEY"
    },
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_PATCH_MODULES = "requests:true"
    },
    {
      DD_APM_ANALYZED_SPANS = "flask|flask.request=1,requests|requests.request=1,aws.dynamodb|dynamodb.command=1,aws.secretsmanager|secretsmanager.command=1"
    },
    {
      OWS_PRODUCT_URL = "https://qa-ows-product.theorchard.io"
    },
    {
      OWS_MARKETING_URL = "https://qa-ows-marketing.theorchard.io"
    },
    {
      OWS_PROJECT_URL = "https://qa-ows-project-manager.theorchard.io"
    },
    {
      MYSQL_PORT = "3306"
    },
    {
      MYSQL_HOST = "qa.db.qaorch.com"
    },
    {
      MYSQL_DATABASE = "art_relations"
    },
    {
      MYSQL_USER = "ows-product-phys"
    },
    {
      FEATURE_DISPLAY_UPC = "0"
    },
    {
      FEATURE_CONFIGURATION_MAPPING = "0"
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_HOME = "/var/.snowflake"
    },
    {
      MYSQL_DELIVERY_HOST = "qa-product-physical-delivery-db.theorchard.io"
    },
    {
      MYSQL_DELIVERY_DATABASE = "product_physical_delivery"
    },
    {
      MYSQL_DELIVERY_USER = "ows-product-physical"
    },
  ]
}

# Setup datadog dashboards.
module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.2"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  application_family                = var.application_family
  notification_endpoints            = var.slack_alert_channel
  escalation_notification_endpoints = var.slack_alert_channel
}