module "ows_product_workflow_build_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.4.0"

  secrets      = ["${var.environment}/${var.service_name}/AUTOMATION_QA_DB_PASS"]
  action_types = ["read"]

  depends_on = [
    module.secrets,
  ]
}

data "aws_iam_policy" "generate_metadata_eo_ecs_run_task_policy" {
  name = "${var.environment}-generate-meta-update-eo-run-ecs-task-policy"
}

resource "aws_iam_policy" "ows_product_workflow_build_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-integration-test-policy"
  policy = module.ows_product_workflow_build_secrets_manager_policy.policy.json
}

data "aws_iam_role" "pipeline_agent_role" {
  name = "prod-jenkins-aws-pipeline-agent"
}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        data.aws_iam_role.pipeline_agent_role.arn,
      ]
    }
  }
}

resource "aws_iam_role" "ows_product_workflow_build_role" {
  name = "${var.environment}-${var.service_name}-integration-test-role"

  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "ows_product_workflow_build_role_policy_attachment" {
  role       = aws_iam_role.ows_product_workflow_build_role.name
  policy_arn = aws_iam_policy.ows_product_workflow_build_secrets_manager_policy.arn
}

# Attach Dynamo qa-ows-request-authorization policy to integration test role.
resource "aws_iam_role_policy_attachment" "qa-ows-request-authorization-dynamo-policy_attachment" {
  role       = aws_iam_role.ows_product_workflow_build_role.name
  policy_arn = module.ows_product_workflow_owsrequest.policy_arn_output
}

# Create IAM user for jenkins qa-ows-product-workflow integration test"
resource "aws_iam_user" "qa-ows-product-workflow-integration-test-user" {
  name = "qa-${var.service_name}-integration-tests"
  tags = {
    application_family = var.application_family
    environment        = var.environment
    role               = "service-user"
    service_name       = var.service_name
    terraformed        = true
  }
}

# Attach Dynamo qa-ows-request-authorization policy to iam user.
resource "aws_iam_user_policy_attachment" "qa-ows-request-authorization-dynamo-policy" {
  user       = aws_iam_user.qa-ows-product-workflow-integration-test-user.name
  policy_arn = module.ows_product_workflow_owsrequest.policy_arn_output
}