module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations.
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-product/integration-test/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "ows_product_integration_test_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family

  additional_tags = {
    secret_type = "integration-tests"
  }
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/${var.service_name}/*",
    ]
  }
}

resource "aws_iam_policy" "secrets_manager_policy" {
  // SecretsManager-qa-ows-product-integration-test-policy is defined in ../iam.tf, so just add -2
  name   = "SecretsManager-${var.environment}-${var.service_name}-policy-2"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

# The role has already been defined with Jenkins pipeline agent assume role policy from ../iam.tf
data "aws_iam_role" "integration_test_role" {
  name = "${var.environment}-${var.service_name}-role"
}

# Attach SecretManager access policy to the integration test role.
resource "aws_iam_role_policy_attachment" "integration_secret_manager_policy_attachment" {
  role       = data.aws_iam_role.integration_test_role.name
  policy_arn = aws_iam_policy.secrets_manager_policy.arn
}