module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-royalties-workflows/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "aws_accounts" {
  source = "git@github.com:theorchard/terraform-aws-accounts-map.git//modules/read_accounts_map?ref=3.0.3"
}

data "aws_iam_policy_document" "cross_account_accounting_qa_policy" {
  statement {
    sid = "AccountingQABucketTrustRelationship"
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/qa-statementdb-instance-role"
      ]
    }

    actions = [
      "s3:ListBucket",
      "s3:ListBucketVersions",
      "s3:ListBucketMultipartUploads"
    ]

    resources = [
      module.s3_qa_royalties_sales_files_bucket.s3_bucket_arn_output
    ]
  }

  statement {
    sid = "AccountingQAPathTrustRelationship"
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/qa-statementdb-instance-role"
      ]
    }

    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion",
      "s3:PutObject",
      "s3:ListMultipartUploadParts",
      "s3:AbortMultipartUpload"
    ]

    resources = [
      "${module.s3_qa_royalties_sales_files_bucket.s3_bucket_arn_output}/*"
    ]
  }
}

module "s3_qa_royalties_sales_files_bucket" {
  source              = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"
  env                 = var.environment
  bucket_name         = "royalties-sales-files"
  kms_key_enabled     = false
  application_family  = var.application_family
  s3_read_only_policy = true

  bucket_policy_overrides = [
    data.aws_iam_policy_document.cross_account_accounting_qa_policy.json,
  ]

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

module "s3_qa_abacus_payments_bucket" {
  source             = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"
  env                = var.environment
  bucket_name        = "abacus-payments"
  kms_key_enabled    = false
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  # CORS Rules
  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = [
        "http://localhost:*",
        "https://abacus.qaorch.com",
        "https://*.pullrequests.qaorch.com"
      ]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    }
  ]
}

module "s3_qa_royalties_airflow_logs_bucket" {
  source             = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"
  env                = var.environment
  bucket_name        = "royalties-airflow-logs"
  kms_key_enabled    = false
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

# Create IAM service user for snowflake stage
resource "aws_iam_user" "iam_user" {
  name = "${var.environment}-${var.service_name}"

  tags = {
    terraformed = true
    role        = "service-user"
  }
}

resource "aws_iam_policy" "s3_qa_royalties_sales_files_bucket_rw_policy" {
  name   = "S3-${module.s3_qa_royalties_sales_files_bucket.s3_bucket_name_output}-RW"
  policy = data.aws_iam_policy_document.s3_qa_royalties_sales_files_bucket_rw_policy_document.json
}

data "aws_iam_policy_document" "s3_qa_royalties_sales_files_bucket_rw_policy_document" {
  statement {
    effect    = "Allow"
    actions   = ["s3:ListAllMyBuckets"]
    resources = ["*"]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:GetBucketLocation",
      "s3:GetBucketVersioning",
      "s3:ListBucket",
      "s3:ListBucketMultipartUploads",
      "s3:ListBucketVersions",

    ]
    resources = [module.s3_qa_royalties_sales_files_bucket.s3_bucket_arn_output]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:AbortMultipartUpload",
      "s3:DeleteObject",
      "s3:GetObject",
      "s3:GetObjectVersion",
      "s3:GetObjectVersionAcl",
      "s3:ListMultipartUploadParts",
      "s3:PutObject",
      "s3:PutObjectAcl",
      "s3:PutObjectVersionAcl",
    ]
    resources = ["${module.s3_qa_royalties_sales_files_bucket.s3_bucket_arn_output}/*"]
  }
}

########################
## abacus-adjustments ##
########################

data "aws_iam_policy_document" "cross_account_accounting_qa_abacus_adjustments_policy" {
  statement {
    sid = "AccountingQABucketTrustRelationship"
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-complete",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-import",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-initialize",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-prepare",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-process-batch",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-validation",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustments-json-import",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustments-json-validation",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-generate-flowthrough-adjustments",
      ]
    }

    actions = [
      "s3:ListBucket",
      "s3:ListBucketVersions",
      "s3:ListBucketMultipartUploads"
    ]

    resources = [
      module.s3_qa_abacus_adjustments_bucket.s3_bucket_arn_output
    ]
  }

  statement {
    sid = "AccountingQAPathTrustRelationship"
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-complete",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-import",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-initialize",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-prepare",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-process-batch",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustment-file-validation",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustments-json-import",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-adjustments-json-validation",
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-qa"]}:role/lambda-qa-lambda-abacus-generate-flowthrough-adjustments",
      ]
    }

    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion",
      "s3:PutObject",
      "s3:DeleteObject",
      "s3:ListMultipartUploadParts",
      "s3:AbortMultipartUpload"
    ]

    resources = [
      "${module.s3_qa_abacus_adjustments_bucket.s3_bucket_arn_output}/*"
    ]
  }
}

module "s3_qa_abacus_adjustments_bucket" {
  source             = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"
  env                = var.environment
  bucket_name        = "abacus-adjustments"
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  # CORS Rules
  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = [
        "http://localhost:*",
        "https://abacus.qaorch.com",
      ]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    }
  ]

  lifecycle_rules_abort_incomplete_multipart_upload_days = [
    {
      enabled = true
      days    = 7
      prefix  = "uploads/"
    }
  ]

  lifecycle_rules_options_current_version_transition = [
    {
      enabled       = true
      prefix        = "uploads/"
      days          = 30
      storage_class = "INTELLIGENT_TIERING"
    },
    {
      enabled       = true
      prefix        = "uploads/"
      days          = 365
      storage_class = "GLACIER"
    }
  ]

  bucket_policy_overrides = [
    data.aws_iam_policy_document.cross_account_accounting_qa_abacus_adjustments_policy.json,
  ]
}

resource "aws_iam_policy" "abacus_adjustments_usage_policy" {
  name   = "S3-qa-abacus-adjustments-usage-policy"
  policy = data.aws_iam_policy_document.abacus_adjustments_usage_policy.json
}

data "aws_iam_policy_document" "abacus_adjustments_usage_policy" {
  statement {
    effect = "Allow"
    actions = [
      "s3:ListBucket",
      "s3:GetBucketLocation",
      "s3:ListBucketMultipartUploads"
    ]
    resources = [module.s3_qa_abacus_adjustments_bucket.s3_bucket_arn_output]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:AbortMultipartUpload",
      "s3:CompleteMultipartUpload",
      "s3:CreateMultipartUpload",
      "s3:DeleteObject",
      "s3:GetObject",
      "s3:ListMultipartUploadParts",
      "s3:PutObject",
      "s3:UploadPart"
    ]
    resources = ["${module.s3_qa_abacus_adjustments_bucket.s3_bucket_arn_output}/*"]
  }
}

#########
## M2M ##
#########

module "m2m_secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"
  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
}