module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-royalties/integration-test/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "integration_test_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 30
}

# reading abacus_adjustments and abacus_quarantine s3 buckets and create policy document
data "aws_s3_bucket" "abacus_adjustments_bucket" {
  bucket = "${var.environment}-abacus-adjustments"
}

data "aws_s3_bucket" "abacus_quarantine_bucket" {
  bucket = "${var.environment}-abacus-quarantine"
}

data "aws_iam_policy_document" "s3_abacus_buckets_write_access_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:DeleteObject"
    ]

    resources = [
      "${data.aws_s3_bucket.abacus_adjustments_bucket.arn}/test_fixtures/*",
      "${data.aws_s3_bucket.abacus_quarantine_bucket.arn}/test_fixtures/*"
    ]
  }
}

data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/*",
    ]
  }
}

# Assume role policy used by Jenkins pipeline agent role
data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# SecretManager Access Policy
resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretManager-${var.environment}-${var.service_name}-access-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

# S3 bucket Access Policy
resource "aws_iam_policy" "abacus_s3_buckets_test_fixtures_write_access_policy" {
  name        = "${var.environment}-abacus-s3-buckets-test-fixtures-write-access-policy"
  description = "Policy to grant write access to test_fixtures folder in qa-abacus-adjustments and qa-abacus-quarantine bucket"
  policy      = data.aws_iam_policy_document.s3_abacus_buckets_write_access_document.json
}

# Jenkins agents will assume this role in order to access SecretManager
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-${var.service_name}-role"
  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

# Attach access policies to Jenkins role.
resource "aws_iam_role_policy_attachment" "integration_policy_attachment" {
    for_each = {
        sm = aws_iam_policy.secrets_manager_policy.arn
        s3 = aws_iam_policy.abacus_s3_buckets_test_fixtures_write_access_policy.arn
    }

  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = each.value
}