module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-salessheets/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.0.2"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.3.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 30
}

module "ows_service_owsrequest" {
  source             = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.1"
  policy_description = "Dynamo-${var.environment}-${var.service_name}-owsrequest"
  environment_name   = var.environment
  service_name       = var.service_name
}

module "ows_salessheets_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.5.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  application_family                       = var.application_family
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 512
  task_memory                              = 1024
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled                    = false
  blocking_waf_enabled                     = false

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/Dynamo-qa-ows-salessheets-owsrequest",
    "arn:aws:iam::437795906767:policy/SQS-qa-sales_sheets-RW",
    "arn:aws:iam::437795906767:policy/S3-qa-orcdbucket-sales_sheets-RW",
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      AR_MYSQL_PORT = "3306"
    },
    {
      BULK_SALESSHEETS_S3_DIRECTORY = "sales-sheets"
    },
    {
      SS_MYSQL_PORT = "3306"
    },
  ]
  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      AR_MYSQL_DATABASE = "${var.environment}/${var.service_name}/AR_MYSQL_DATABASE"
    },
    {
      AR_MYSQL_HOST = "${var.environment}/${var.service_name}/AR_MYSQL_HOST"
    },
    {
      AR_MYSQL_PASSWORD = "${var.environment}/${var.service_name}/AR_MYSQL_PASSWORD"
    },
    {
      AR_MYSQL_USER = "${var.environment}/${var.service_name}/AR_MYSQL_USER"
    },
    {
      SS_MYSQL_DATABASE = "${var.environment}/${var.service_name}/SS_MYSQL_DATABASE"
    },
    {
      SS_MYSQL_HOST = "${var.environment}/${var.service_name}/SS_MYSQL_HOST"
    },
    {
      SS_MYSQL_PASSWORD = "${var.environment}/${var.service_name}/SS_MYSQL_PASSWORD"
    },
    {
      SS_MYSQL_USER = "${var.environment}/${var.service_name}/SS_MYSQL_USER"
    },
  ]
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.10.7"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  notification_endpoints            = var.application_alert_channel
  escalation_notification_endpoints = var.application_alert_channel
}

module "ows_salessheets_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=6.3.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  rds_master_username = "ows_salessheets_admin"
  rds_master_password = "s0mePass!changme"

  rds_cluster_instance_class                = "db.t4g.medium"
  rds_cluster_instance_count                = "1"
  rds_db_cluster_parameter_group_name       = "aurora-mysql80sync"
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  rds_engine                                = "aurora-mysql"
  rds_engine_version                        = "8.0.mysql_aurora.3.05.2"
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  rds_performance_insights_enabled          = false
  enabled_cloudwatch_logs_exports           = ["audit", "error", "general"]
  custom_kms_key_enabled                    = true

  vpc_id          = module.vpc_info.vpc_id
  route53_zone_id = data.aws_route53_zone.route53_zone.zone_id
}

module "ows_salessheets_rds_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/rds?ref=6.10.7"

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name

  notification_endpoints            = var.application_alert_channel
  escalation_notification_endpoints = var.application_alert_channel
}

data "aws_iam_policy_document" "build_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [for s in values(module.secrets) : s.secret_arn]
  }
}

# Assume role policy used by Jenkins pipeline agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# SecretManager Access Policy
resource "aws_iam_policy" "integration_test_policy" {
  name   = "${var.environment}-${var.service_name}-integration-test-policy"
  policy = data.aws_iam_policy_document.build_policy_document.json
}

# Jenkins pipeline agents will assume this role in order to access SecretManager
resource "aws_iam_role" "integration_test_role" {
  name               = "${var.environment}-${var.service_name}-integration-test-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach SecretManager access policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "policy_attachment" {
  role       = aws_iam_role.integration_test_role.id
  policy_arn = aws_iam_policy.integration_test_policy.arn
}