module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-sound-recordings/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.0.2"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "s3_sr_versions_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"

  application_family = var.application_family
  env                = var.environment
  bucket_name        = var.sr_versions_bucket

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

data "aws_iam_policy_document" "s3_sr_versions_ows_policy_document" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion"
    ]

    resources = [
      "${module.s3_sr_versions_bucket.s3_bucket_arn_output}/*",
    ]
  }

  statement {
    actions = [
      "s3:ListBucket",
      "s3:ListBucketVersions"
    ]

    resources = [
      module.s3_sr_versions_bucket.s3_bucket_arn_output,
    ]
  }
}

data "aws_iam_policy" "s3_sr_delivery_audit_bucket_read_only_policy" {
  name = "S3-${var.environment}-${var.sr_delivery_audit_bucket}-read-only"
}

resource "aws_iam_policy" "s3_sr_versions_ows_policy" {
  name   = "S3-${var.environment}-${var.sr_versions_bucket}-R-policy"
  policy = data.aws_iam_policy_document.s3_sr_versions_ows_policy_document.json
}

module "ows_sound_recordings_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  application_family = var.application_family
  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  teams              = [var.environment]
}

module "ows_sound_recordings_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git?ref=1.0.1"

  environment_name = var.environment
  service_name     = var.service_name
}

data "aws_iam_policy_document" "secretsmanager_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:GetSecretValue"
    ]
    resources = [
      "arn:aws:secretsmanager:*:*:secret:qa/python-orchard-features/*",
      "arn:aws:secretsmanager:*:*:secret:qa/python-orchard-features/"
    ]
  }
}

resource "aws_iam_policy" "secretsmanager_policy" {
  name   = "${var.environment}-secretsmanager-ows-sound-recordings-policy"
  policy = data.aws_iam_policy_document.secretsmanager_policy_document.json
}

module "ows_sound_recordings_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git?ref=5.6.0"

  providers = {
    aws.dns = aws.networking
  }

  application_family                            = var.application_family
  environment                                   = var.environment
  service_name                                  = var.service_name
  aws_region                                    = var.aws_region
  desired_task_count                            = 2
  minimum_capacity                              = 4
  maximum_capacity                              = 20
  task_cpu                                      = 4096
  task_memory                                   = 8192
  route53_zone_id                               = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name      = "orch-elb-logs"
  vpc_id                                        = module.vpc_info.vpc_id
  https_listener_certificate_id                 = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  fargate_service_subnets                       = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                         = module.vpc_info.default_private_subnet_ids
  blocking_waf_enabled                          = true
  health_check_grace_period_seconds             = 120
  container_start_period_seconds                = 120
  autoscaling_active_connections_policy_enabled = true
  target_deregistration_delay                   = 120

  iam_managed_policy_attachments = [
    module.ows_sound_recordings_owsrequest.policy_arn_output,
    aws_iam_policy.s3_sr_versions_ows_policy.arn,
    data.aws_iam_policy.s3_sr_delivery_audit_bucket_read_only_policy.arn,
    aws_iam_policy.secretsmanager_policy.arn,
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      S3_VERSION_BUCKET = module.s3_sr_versions_bucket.s3_bucket_name_output
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_HOME = "/var/.snowflake"
    },
    {
      NEO4J_MAX_CONN_POOLSIZE = 25
    }
  ]

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      SNOWFLAKE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_KEY"
    }
  ]
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "ows_sound_recordings_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.10.7"

  application_family = var.application_family
  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.service_name

  notification_endpoints            = "@slack-collections-qa-alarms"
  escalation_notification_endpoints = "@slack-collections-qa-alarms"

  service_4xx_monitor_enabled  = false
  ok_number_5xx                = 0
  warning_number_5xx           = 5
  warning_recovery_number_5xx  = 0
  critical_number_5xx          = 10
  critical_recovery_number_5xx = 1
  service_cpu_time_window      = "last_10m"
}


module "s3_sr_delivery_upload_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.1"

  application_family = var.application_family
  env                = var.environment
  bucket_name        = var.sr_delivery_upload_bucket

  # CORS Rules
  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = [
        "http://localhost:*"
      ]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    }
  ]

  lifecycle_rules_abort_incomplete_multipart_upload_days = [
    {
      prefix  = ""
      enabled = true
      days    = 1
    }
  ]

  lifecycle_rules_options_current_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 1
    }
  ]

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}