module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations!
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-timed-release/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

module "ows_service_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.service_name
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

data "aws_iam_role" "lambda_timed_release_scheduling_role" {
  name = "${var.environment}-lambda-timed-release-scheduling-role"
}

data "aws_iam_role" "timed_release_ws_scheduling_role" {
  name = "${var.environment}-timed-release-ws-scheduling-role"
}

data "aws_lambda_function" "lambda_timed_release_trigger_product_update" {
  function_name = "${var.environment}-lambda-timed-release-trigger-product-update"
}

data "aws_lambda_function" "lambda_timed_release_notify_label_manager" {
  function_name = "${var.environment}-lambda-timed-release-notify-label-manager"
}

data "aws_lambda_function" "lambda_timed_release_ws_send_notification" {
  function_name = "${var.environment}-lambda-timed-release-ws-send-notification"
}

data "aws_sfn_state_machine" "sfn_ws_scheduled_product_metadata_update" {
  name = "${var.environment}-sfn-ws-scheduled-product-metadata-update"
}

resource "aws_iam_policy" "timed_release_scheduling_policy" {
  name        = "${var.environment}-${var.service_name}-scheduling-policy"
  description = "${var.environment}-${var.service_name}-scheduling-policy"
  policy      = data.aws_iam_policy_document.timed_release_scheduling_policy_document.json
}

data "aws_iam_policy" "timed_release_start_execution" {
  name = "StepFunctions-${var.environment}-sfn-scheduled-product-metadata-update-StartExecution"
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "timed_release_scheduling_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "iam:PassRole"
    ]

    resources = [
      data.aws_iam_role.lambda_timed_release_scheduling_role.arn
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "scheduler:CreateSchedule",
      "scheduler:DeleteSchedule",
      "scheduler:GetSchedule",
      "scheduler:UpdateSchedule"
    ]

    resources = [
      "arn:aws:scheduler:${var.aws_region}:437795906767:schedule/${var.environment}-lambda-timed-release-product-update-schedules/*"
    ]
  }
}

data "aws_iam_policy_document" "ows_timed_release_ws_scheduling_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "iam:PassRole"
    ]

    resources = [
      data.aws_iam_role.timed_release_ws_scheduling_role.arn
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "scheduler:CreateSchedule",
      "scheduler:DeleteSchedule",
      "scheduler:GetSchedule",
      "scheduler:UpdateSchedule"
    ]

    resources = [
      "arn:aws:scheduler:${var.aws_region}:${data.aws_caller_identity.current.account_id}:schedule/${var.environment}-lambda-timed-release-ws-product-schedules/*"
    ]
  }
}

resource "aws_iam_policy" "ows_timed_release_ws_scheduling_policy" {
  name        = "${var.environment}-${var.service_name}-ws-scheduling-policy"
  description = "Policy to give iam:PassRole and CRUD access on the schedules for workstaion"
  policy      = data.aws_iam_policy_document.ows_timed_release_ws_scheduling_policy_document.json
}

module "ows_timed_release_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.3"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  application_family                       = var.application_family
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 1024
  task_memory                              = 2048
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled                    = false
  blocking_waf_enabled                     = false
  fargate_service_subnets                  = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                    = module.vpc_info.default_private_subnet_ids
  splitio_enabled                          = true

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/Dynamo-qa-ows-timed-release-owsrequest",
    aws_iam_policy.timed_release_scheduling_policy.arn,
    data.aws_iam_policy.timed_release_start_execution.arn,
    aws_iam_policy.ows_timed_release_ws_scheduling_policy.arn
  ]

  https_listener_allow_prefix_list_names = [
    "${var.environment}-supply-chain-private-subnet-prefix-list",
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      RDS_MYSQL_PORT = var.RDS_MYSQL_PORT
    },
    {
      AR_MYSQL_DATABASE = "art_relations"
    },
    {
      AR_MYSQL_HOST = "qa.db.qaorch.com"
    },
    {
      AR_MYSQL_USER = "ows-timed-release"
    },
    {
      SCHEDULER_ROLE_ARN = data.aws_iam_role.lambda_timed_release_scheduling_role.arn
    },
    {
      WS_SCHEDULER_ROLE_ARN = data.aws_iam_role.timed_release_ws_scheduling_role.arn
    },
    {
      SCHEDULER_GROUP = "${var.environment}-lambda-timed-release-product-update-schedules"
    },
    {
      WS_SCHEDULER_GROUP = "${var.environment}-lambda-timed-release-ws-product-schedules"
    },
    {
      TRIGGER_PRODUCT_UPDATE_LAMBDA_ARN = data.aws_lambda_function.lambda_timed_release_trigger_product_update.arn
    },
    {
      NOTIFY_LABEL_MANAGER_LAMBDA_ARN = data.aws_lambda_function.lambda_timed_release_notify_label_manager.arn
    },
    {
      AWS_REGION = "us-east-1"
    },
    {
      EXECUTE_STEP_FUNCTION_ARN = "arn:aws:states:us-east-1:437795906767:stateMachine:qa-sfn-scheduled-product-metadata-update"
    },
    {
      TRIGGER_SFN_WS_UPDATE_METADATA_ARN = data.aws_sfn_state_machine.sfn_ws_scheduled_product_metadata_update.arn
    },
    {
      WS_SEND_NOTIFICATION_LAMBDA_ARN = data.aws_lambda_function.lambda_timed_release_ws_send_notification.arn
    },
  ]
  secrets = [
    {
      LOGGER_DSN = "${var.environment}/${var.service_name}/LOGGER_DSN"
    },
    {
      RDS_MYSQL_DATABASE = "${var.environment}/${var.service_name}/RDS_MYSQL_DATABASE"
    },
    {
      RDS_MYSQL_HOST = "${var.environment}/${var.service_name}/RDS_MYSQL_HOST"
    },
    {
      RDS_DB_URL = "${var.environment}/${var.service_name}/RDS_DB_URL"
    },
    {
      RDS_MYSQL_PASSWORD = "${var.environment}/${var.service_name}/RDS_MYSQL_PASSWORD"
    },
    {
      RDS_MYSQL_USER = "${var.environment}/${var.service_name}/RDS_MYSQL_USER"
    },
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      AR_MYSQL_PASSWORD = "${var.environment}/${var.service_name}/AR_MYSQL_PASSWORD"
    },
    {
      SPLITIO_API_KEY = "${var.environment}/split/API_KEY"
    }
  ]
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.1"

  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  teams                             = [var.application_family]
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
}

resource "aws_rds_cluster_parameter_group" "ows_timed_release_cluster_parameter_group" {
  family = "aurora-mysql8.0"
  name   = "${var.environment}-${var.service_name}-aurora-mysql80"

  lifecycle {
    create_before_destroy = true
  }

  parameter {
    name         = "aurora_binlog_replication_max_yield_seconds"
    value        = "0"
    apply_method = "immediate"
  }

  parameter {
    name         = "binlog_format"
    value        = "ROW"
    apply_method = "pending-reboot"
  }

  parameter {
    name         = "character_set_client"
    value        = "utf8mb4"
    apply_method = "immediate"
  }

  parameter {
    name         = "character_set_connection"
    value        = "utf8mb4"
    apply_method = "immediate"
  }

  parameter {
    name         = "character_set_database"
    value        = "utf8mb4"
    apply_method = "immediate"
  }

  parameter {
    name         = "character_set_filesystem"
    value        = "binary"
    apply_method = "immediate"
  }

  parameter {
    name         = "character_set_results"
    value        = "utf8mb4"
    apply_method = "immediate"
  }

  parameter {
    name         = "character_set_server"
    value        = "utf8mb4"
    apply_method = "immediate"
  }

  parameter {
    name         = "collation_connection"
    value        = "utf8mb4_general_ci"
    apply_method = "immediate"
  }

  parameter {
    name         = "collation_server"
    value        = "utf8mb4_general_ci"
    apply_method = "immediate"
  }

  parameter {
    name         = "log_bin_trust_function_creators"
    value        = "1"
    apply_method = "immediate"
  }

  parameter {
    name  = "max_connections"
    value = "180"
  }
}

module "ows_timed_release_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=8.0.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  rds_master_username = "ows_timed_release_admin"
  rds_master_password = "s0mePass!changme"

  rds_cluster_instance_class                = "db.t4g.medium"
  rds_cluster_instance_count                = "1"
  rds_db_cluster_parameter_group_name       = aws_rds_cluster_parameter_group.ows_timed_release_cluster_parameter_group.name
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  rds_engine                                = "aurora-mysql"
  rds_engine_version                        = "8.0"
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  rds_performance_insights_enabled          = false
  enabled_cloudwatch_logs_exports           = ["audit", "error", "general"]
  custom_kms_key_enabled                    = true

  vpc_id          = module.vpc_info.vpc_id
}

# Create IAM user for jenkins qa-ows-timed-release integration test"
resource "aws_iam_user" "qa-ows-timed-release-integration-test-user" {
  name = "qa-${var.service_name}-integration-tests"
  tags = {
    application_family = var.application_family
    environment        = var.environment
    role               = "service-user"
    service_name       = var.service_name
    terraformed        = true
  }
}

# Attach Dynamo qa-ows-request-authorization policy to iam user.
resource "aws_iam_user_policy_attachment" "qa-ows-request-authorization-dynamo-policy" {
  user       = aws_iam_user.qa-ows-timed-release-integration-test-user.name
  policy_arn = "arn:aws:iam::437795906767:policy/Dynamo-qa-ows-timed-release-owsrequest"
}