module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/publishing-delivery-recorder/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "streamlit_service_fargate" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.8.1"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family

  desired_task_count                       = 1
  minimum_capacity                         = 1
  maximum_capacity                         = 1
  task_cpu                                 = 256
  task_memory                              = 512
  task_type                                = "web_service"
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  fargate_service_subnets                  = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                    = module.vpc_info.default_private_subnet_ids
  health_check_path                        = "/_stcore/health"

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      QA_GRAPHQL_URL = "https://qa-graphql-router.theorchard.io/graphql"
    },
    {
      PROD_GRAPHQL_URL = "https://prod-graphql-router.theorchard.io/graphql"
    },
    {
      AUTH_REDIRECT_URI = "https://${var.environment}-${var.service_name}.theorchard.io/oauth2callback"
    },
    {
      AUTH0_CLIENT_ID = var.auth0_client_id
    },
    {
      AUTH0_SERVER_METADATA_URL = var.auth0_server_metadata_url
    },
    {
      AUTH0_CLIENT_KWARGS_PROMPT = "login"
    },
  ]

  secrets = [
    {
      AUTH_COOKIE_SECRET = "${var.environment}/${var.service_name}/AUTH_COOKIE_SECRET"
    },
    {
      AUTH0_CLIENT_SECRET = "${var.environment}/${var.service_name}/AUTH0_CLIENT_SECRET"
    },
  ]
  iam_managed_policy_attachments = []
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.7"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.service_name
  application_family = var.application_family
  teams              = [var.application_family]

  service_4xx_monitor_enabled = false

  service_cpu_monitor_evaluation_function = "avg"
  service_cpu_time_window                 = "last_10m"

  notification_endpoints            = "@slack-publishing-alerts"
  escalation_notification_endpoints = "@slack-publishing-alerts"
}