module "refresh_aura_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.3.0"

  secrets      = [
    "${var.environment}/${var.service_name}/SENTRY_DSN",
    "${var.environment}/${var.service_name}/${var.secrets_manager_secret_names[0]}",
    "${var.environment}/${var.service_name}/${var.secrets_manager_secret_names[1]}",
  ]
  action_types = ["read"]

  depends_on = [
    module.refresh_aura_secrets,
  ]
}

resource "aws_iam_policy" "refresh_aura_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-execution-policy"
  policy = module.refresh_aura_secrets_manager_policy.policy.json
}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "refresh_aura_role" {
  name = "${var.environment}-${var.service_name}-execution-role"

  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "refresh_aura_role_policy_attachment" {
  role       = aws_iam_role.refresh_aura_role.name
  policy_arn = aws_iam_policy.refresh_aura_secrets_manager_policy.arn
}