module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = "abacus"
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/royalty_accounting/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "s3_bucket_policy" {
  statement {
    actions = [
      "s3:AbortMultipartUpload",
      "s3:DeleteObject",
      "s3:GetBucketLocation",
      "s3:GetBucketObjectLockConfiguration",
      "s3:GetBucketVersioning",
      "s3:GetLifecycleConfiguration",
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:GetObjectLegalHold",
      "s3:GetObjectRetention",
      "s3:GetObjectTorrent",
      "s3:GetObjectVersion",
      "s3:GetObjectVersionAcl",
      "s3:GetObjectVersionTorrent",
      "s3:GetReplicationConfiguration",
      "s3:ListBucket",
      "s3:ListBucketMultipartUploads",
      "s3:ListBucketVersions",
      "s3:ListMultipartUploadParts",
      "s3:PutObject",
      "s3:PutObjectAcl"
    ]
    resources = [
      "arn:aws:s3:::qa-abacus-static-data/",
      "arn:aws:s3:::qa-abacus-static-data/*",
      "arn:aws:s3:::qa-abacus-static-data",
      "arn:aws:s3:::qa-royalties-sales-files/",
      "arn:aws:s3:::qa-royalties-sales-files/*",
      "arn:aws:s3:::qa-royalties-sales-files"
    ]
  }
}

data "aws_route53_zone" "orchard_networking" {
  provider = aws.networking

  name = "theorchard.io"
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = "royalty_accounting"
  secret_name        = each.value
  application_family = var.application_family
}

module "s3_qa_abacus_static_data_bucket" {
  source             = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.14.1"
  env                = var.environment
  bucket_name        = "abacus-static-data"
  kms_key_enabled    = false
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

resource "aws_iam_policy" "royalty_accounting_snowflake_stage_iam_user" {
  name   = "royalty_accounting_snowflake_stage_policy"
  path   = "/"
  policy = data.aws_iam_policy_document.s3_bucket_policy.json
}

# IAM user for s3.
resource "aws_iam_user" "royalty_accounting_iam_user" {
  name = "${var.environment}-${var.service_name}"
  tags = {
    terraformed = true
    role        = "service-user"
  }
}

resource "aws_iam_user_policy_attachment" "royalty_accounting_snowflake_stage_s3" {
  user       = aws_iam_user.royalty_accounting_iam_user.name
  policy_arn = aws_iam_policy.royalty_accounting_snowflake_stage_iam_user.arn
}

resource "aws_iam_group_policy_attachment" "royalty_accounting_more_snowflake_stage_s3" {
  group      = "royalty-accounting-more"
  policy_arn = aws_iam_policy.royalty_accounting_snowflake_stage_iam_user.arn
}

# Create IAM user for db-deployment
resource "aws_iam_user" "royalty_accounting_db_deploy_qa_iam_user" {
  name = "${var.environment}-${var.service_name}-db-deploy"
  tags = {
    terraformed = true
    role        = "service-user"
  }
}

data "aws_iam_policy_document" "qa_db_creds_read_only_policy_document" {
  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:GetObject"
    ]
    resources = [
      "arn:aws:s3:::nickelback/db-deploy/${var.environment}/royalty_accounting/db.properties",
      "arn:aws:s3:::nickelback/db-deploy/uat/royalty_accounting/db.properties"
    ]
  }

  statement {
    actions = [
      "ecr:GetAuthorizationToken",
      "ecr:BatchCheckLayerAvailability",
      "ecr:GetDownloadUrlForLayer",
      "ecr:GetRepositoryPolicy",
      "ecr:DescribeRepositories",
      "ecr:ListImages",
      "ecr:DescribeImages",
      "ecr:BatchGetImage",
      "ecr:GetLifecyclePolicy",
      "ecr:GetLifecyclePolicyPreview",
      "ecr:ListTagsForResource",
      "ecr:DescribeImageScanFindings"
    ]

    resources = [
      "arn:aws:ecr:*:${data.aws_caller_identity.current.account_id}:repository/royalties-liquibase-runner",
      "arn:aws:ecr:*:${data.aws_caller_identity.current.account_id}:repository/docker-parent-images"
    ]
  }

  statement {
    actions = [
      "ecr:GetAuthorizationToken"
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "qa_db_creds_read_only_policy" {
  name   = "${var.environment}-royalty-accounting-database-creds-policy"
  policy = data.aws_iam_policy_document.qa_db_creds_read_only_policy_document.json
}

# Attach IAM policy to IAM user
resource "aws_iam_user_policy_attachment" "qa_db_creds_read_only_policy_attachment" {
  user       = aws_iam_user.royalty_accounting_db_deploy_qa_iam_user.name
  policy_arn = aws_iam_policy.qa_db_creds_read_only_policy.arn
}