module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.1.0"
  environment        = var.env
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/split-synchronizer/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.3.0"

  environment = var.env
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

module "elasticache" {
  # checkov:skip=CKV_AWS_30:ElastiCache encryption in transit requires client library update.
  # checkov:skip=CKV_AWS_31:ElastiCache encryption in transit requires client library update.
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=4.0.2"

  providers = {
    aws.dns = aws.networking
  }

  environment                      = var.env
  service_name                     = var.service_name
  cache_engine                     = "redis"
  cache_subnet_group_name          = "prod-vpc-orchard-subnet"
  cache_node_type                  = "cache.t4g.micro"
  cache_node_count                 = 2
  cache_parameter_group_name       = "default.redis7"
  redis_engine_version             = "7.1"
  vpc_id                           = module.vpc_info.vpc_id
  application_family               = var.application_family
  additional_cidr_blocks_enabled   = true
  cache_transit_encryption_enabled = false
  additional_cidr_blocks = [
    "10.40.0.0/22",
    "192.168.31.0/24",
    "192.168.33.0/24",
  ]

  # allow access from VPN and dev boxes
  vpn_prefix_list_names = [
    "vpn-ny-users",
    "shared-orcd-dev-box-private-subnet-prefix-list",
  ]
}

module "split_synchronizer_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.7.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.env
  service_name                             = var.service_name
  aws_region                               = var.region
  commit_sha                               = "latest"
  container_port                           = "3010"
  task_type                                = "web_service"
  desired_task_count                       = 1
  task_cpu                                 = 256
  task_memory                              = 512
  maximum_capacity                         = 1
  minimum_capacity                         = 1
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  health_check_path                        = "/admin/ping"
  application_family                       = var.application_family

  iam_managed_policy_attachments = [
    "arn:aws:iam::aws:policy/CloudWatchFullAccess"
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      SPLIT_SYNC_REDIS_HOST = module.elasticache.redis_primary_endpoint_address
    },
    {
      SPLIT_SYNC_REDIS_PORT = "6379"
    },
    {
      SPLIT_SYNC_ADVANCED_PARAMETERS = "-config /var/app/config.json"
    }
  ]

  secrets = [
    {
      SPLIT_SYNC_API_KEY = "${var.env}/${var.service_name}/SPLIT_SYNC_API_KEY"
    }
  ]
}