module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.application_family
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/standalone-frontends/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_route53_zone" "route53_zone_networking" {
  provider = aws.networking

  name = "theorchard.io"
}

data "aws_route53_zone" "pullrequests_root_zones" {
  for_each     = var.dns_zones_to_support_for_pullrequests
  name         = each.value["domain_name"]
  private_zone = each.value["is_zone_private"]
}

data "aws_acm_certificate" "root_zone" {
  for_each    = var.dns_zones_to_support_for_pullrequests
  domain      = "*.${each.value["domain_name"]}"
  statuses    = ["ISSUED"]
  most_recent = true
}

data "aws_acm_certificate" "pullrequests" {
  for_each    = var.dns_zones_to_support_for_pullrequests
  domain      = "*.pullrequests.${each.value["domain_name"]}"
  statuses    = ["ISSUED"]
  most_recent = true
}

data "aws_acm_certificate" "qapdesuite_root_zone" {
  domain   = "*.${var.qapdesuite_domain_name}"
  statuses = ["ISSUED"]
}

data "aws_acm_certificate" "qapdesuite_pullrequests" {
  domain   = "*.pullrequests.${var.qapdesuite_domain_name}"
  statuses = ["ISSUED"]
}

data "aws_subnet" "private_1" {
  filter {
    name   = "tag:Name"
    values = ["private01"]
  }
}

data "aws_subnet" "private_2" {
  filter {
    name   = "tag:Name"
    values = ["private02"]
  }
}

resource "aws_lb_listener_certificate" "frontend_standalone_pullrequests" {
  for_each        = var.dns_zones_to_support_for_pullrequests
  listener_arn    = module.ows_standalone_frontends_fargate_environment.fargate_load_balancer_https_listener_arn
  certificate_arn = data.aws_acm_certificate.pullrequests[each.key].arn
}

resource "aws_lb_listener_certificate" "frontend_standalone_root_zone" {
  for_each        = var.dns_zones_to_support_for_pullrequests
  listener_arn    = module.ows_standalone_frontends_fargate_environment.fargate_load_balancer_https_listener_arn
  certificate_arn = data.aws_acm_certificate.root_zone[each.key].arn
}

resource "aws_lb_listener_certificate" "qapdesuite_frontend_standalone_pullrequests" {
  listener_arn    = module.ows_standalone_frontends_fargate_environment.fargate_load_balancer_https_listener_arn
  certificate_arn = data.aws_acm_certificate.qapdesuite_pullrequests.arn
}

resource "aws_lb_listener_certificate" "qapdesuite_frontend_standalone_root_zone" {
  listener_arn    = module.ows_standalone_frontends_fargate_environment.fargate_load_balancer_https_listener_arn
  certificate_arn = data.aws_acm_certificate.qapdesuite_root_zone.arn
}

module "ows_standalone_frontends_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.7.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  application_family                       = var.application_family
  commit_sha                               = "latest"
  container_port                           = "80"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 256
  task_memory                              = 512
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  health_check_path                        = "/"
  health_check_grace_period_seconds        = 300
  container_start_period_seconds           = 300
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids
  environment_variables = [
    {
      Environment = var.environment
    }
  ]
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.6"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  service_4xx_monitor_enabled       = false
  application_family                = var.application_family
  notification_endpoints            = "@slack-the-build-is-broken"
  escalation_notification_endpoints = "@slack-the-build-is-broken"
}

module "frontend_content_review_standalone_sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  service_name       = "${var.service_name}-content-review-standalone"
  application_family = var.application_family
  teams              = [var.environment]
}

resource "aws_route53_record" "frontend-standalone-cname" {
  for_each = toset(var.cname_records)

  zone_id = data.aws_route53_zone.route53_zone.zone_id
  name    = each.key
  type    = "CNAME"
  ttl     = "60"
  records = ["${module.ows_standalone_frontends_fargate_environment.non_prod_fargate_service_route53_record_fqdn_output}."]
}

resource "aws_route53_record" "frontend-standalone-cname-networking" {
  provider = aws.networking
  for_each = toset(var.cname_records)

  zone_id = data.aws_route53_zone.route53_zone_networking.zone_id
  name    = each.key
  type    = "CNAME"
  ttl     = "60"
  records = ["${module.ows_standalone_frontends_fargate_environment.non_prod_fargate_service_route53_record_fqdn_output}."]
}

resource "aws_route53_record" "frontend-content-standalone-cname" {
  zone_id = data.aws_route53_zone.route53_zone.zone_id
  name    = "qa-frontend-content-standalone.theorchard.io"
  type    = "CNAME"
  ttl     = "60"
  records = [module.ows_standalone_frontends_fargate_environment.non_prod_fargate_service_route53_record_fqdn_output]
}

resource "aws_route53_record" "frontend-content-standalone-cname-networking" {
  provider = aws.networking

  zone_id = data.aws_route53_zone.route53_zone_networking.zone_id
  name    = "qa-frontend-content-standalone.theorchard.io"
  type    = "CNAME"
  ttl     = "60"
  records = [module.ows_standalone_frontends_fargate_environment.non_prod_fargate_service_route53_record_fqdn_output]
}

resource "aws_route53_record" "frontend-moneyhub-standalone-cname" {
  zone_id = data.aws_route53_zone.route53_zone.zone_id
  name    = "qa-frontend-moneyhub-standalone.theorchard.io"
  type    = "CNAME"
  ttl     = "60"
  records = [module.ows_standalone_frontends_fargate_environment.non_prod_fargate_service_route53_record_fqdn_output]
}

resource "aws_route53_record" "frontend-moneyhub-standalone-cname-networking" {
  provider = aws.networking

  zone_id = data.aws_route53_zone.route53_zone_networking.zone_id
  name    = "qa-frontend-moneyhub-standalone.theorchard.io"
  type    = "CNAME"
  ttl     = "60"
  records = [module.ows_standalone_frontends_fargate_environment.non_prod_fargate_service_route53_record_fqdn_output]
}

resource "aws_route53_record" "pullrequests_wildcard_cname" {
  for_each = var.dns_zones_to_support_for_pullrequests
  zone_id  = data.aws_route53_zone.pullrequests_root_zones[each.key].zone_id
  name     = "*.pullrequests.${each.value["domain_name"]}"
  type     = "CNAME"
  ttl      = "60"
  records  = [module.ows_standalone_frontends_fargate_environment.non_prod_fargate_service_route53_record_fqdn_output]
}