module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}
# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/standalone-frontends/pullrequests/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "zone" {
  for_each     = var.dns_zones_to_support_for_pullrequests
  name         = each.value["domain_name"]
  private_zone = each.value["is_zone_private"]
}

resource "aws_acm_certificate" "tls_cert" {
  for_each          = var.dns_zones_to_support_for_pullrequests
  domain_name       = "*.pullrequests.${data.aws_route53_zone.zone[each.key].name}"
  validation_method = each.value["validation_method"]

  options {
    certificate_transparency_logging_preference = "ENABLED"
  }

  tags = {
    environment  = var.environment
    service_name = var.service_name
    terraformed  = "true"
  }

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_route53_record" "qaawal_dns_validation_record" {
  for_each = {
    for validation_object in aws_acm_certificate.tls_cert["qaawal"].domain_validation_options : validation_object.domain_name => {
      name   = validation_object.resource_record_name
      record = validation_object.resource_record_value
      type   = validation_object.resource_record_type
    }
  }

  allow_overwrite = true
  name            = each.value.name
  records         = [each.value.record]
  ttl             = 60
  type            = each.value.type
  zone_id         = data.aws_route53_zone.zone["qaawal"].zone_id
}

resource "aws_route53_record" "qakollectivenr_dns_validation_record" {
  for_each = {
    for validation_object in aws_acm_certificate.tls_cert["qakollectivenr"].domain_validation_options : validation_object.domain_name => {
      name   = validation_object.resource_record_name
      record = validation_object.resource_record_value
      type   = validation_object.resource_record_type
    }
  }

  allow_overwrite = true
  name            = each.value.name
  records         = [each.value.record]
  ttl             = 60
  type            = each.value.type
  zone_id         = data.aws_route53_zone.zone["qakollectivenr"].zone_id
}

resource "aws_acm_certificate_validation" "certificate_validation" {
  for_each        = var.dns_zones_to_support_for_pullrequests
  certificate_arn = aws_acm_certificate.tls_cert[each.key].arn
}