module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/standalone-frontends/pullrequests/qapdesuite/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "aws_acm_certificate" "qapdesuite_tls_cert" {
  # checkov:skip=CKV2_AWS_71: Ensure AWS ACM Certificate domain name does not include wildcards
  domain_name               = "*.pullrequests.${var.domain_name}"
  validation_method         = "DNS"

  options {
    certificate_transparency_logging_preference = "ENABLED"
  }

  lifecycle {
    create_before_destroy = true
  }
}

data "cloudflare_zone" "qapdesuite_zone" {
  filter = {
    name = var.domain_name
  }
}

resource "cloudflare_dns_record" "qapdesuite_dns_validation_record" {
  for_each = {
    for validation_object in aws_acm_certificate.qapdesuite_tls_cert.domain_validation_options : validation_object.domain_name => {
      name    = validation_object.resource_record_name
      content = validation_object.resource_record_value
      type    = validation_object.resource_record_type
    }
  }

  zone_id = data.cloudflare_zone.qapdesuite_zone.zone_id
  name    = trimsuffix(each.value.name, ".")
  content = trimsuffix(each.value.content, ".")
  type    = each.value.type
  ttl     = 60
}

resource "aws_acm_certificate_validation" "qapdesuite_certificate_validation" {
  certificate_arn         = aws_acm_certificate.qapdesuite_tls_cert.arn
  validation_record_fqdns = aws_acm_certificate.qapdesuite_tls_cert.domain_validation_options[*].resource_record_name
}

resource "cloudflare_dns_record" "pullrequests_cname" {
  for_each = var.pullrequest_subdomains
  zone_id = data.cloudflare_zone.qapdesuite_zone.zone_id
  name    = "${each.value}.${var.domain_name}"
  content = "qa-standalone-frontends.theorchard.io"
  type    = "CNAME"
  ttl     = 60
}