module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

data "aws_caller_identity" "current" {}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/swf-feed-ingestion/amazon-datapulse/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_iam_policy" "existing_swf_policies" {
  for_each = toset(local.existing_swf_policy_names)
  name     = each.value
}

module "fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                  = var.environment
  service_name                 = var.service_name
  application_family           = var.application_family
  secrets_manager_service_name = var.secrets_manager_service_name
  non_ecr_image                = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/swf-feed-ingestion:latest"
  aws_region                   = var.aws_region
  commit_sha                   = "latest"
  container_port               = "8080"
  task_type                    = "worker"
  desired_task_count           = 1
  task_cpu                     = 1024
  task_memory                  = 2048
  maximum_capacity             = 1
  minimum_capacity             = 1
  vpc_id                       = module.vpc_info.vpc_id

  iam_managed_policy_attachments = [
    for policy in data.aws_iam_policy.existing_swf_policies : policy.arn
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      AWS_REGION = var.aws_region
    },
    {
      SWF_DOMAIN = local.swf_domain
    },
    {
      GARCON_FLOW_NAME = var.flow_name
    },
    {
      FEED_INGESTION_DATA_BUCKET = var.feed_ingestion_data_bucket
    },
    {
      FEED_INGESTION_TABLE = local.feed_ingestion_table
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SENTRY_DSN  = module.sentry_project.sentry_key_dsn_public_output,
    },
  ]

  secrets = [
    {
      SNOWFLAKE_KEY = "${var.environment}/${var.secrets_manager_service_name}/SNOWFLAKE_KEY"
    },
  ]
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.secrets_manager_service_name
  secret_name        = each.value
  application_family = var.application_family
}

module "sentry_project" {
  source                       = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"
  service_name                 = var.service_name
  application_family           = var.application_family
  environment                  = var.environment
  teams                        = [var.environment]
  platform                     = "python"
}

module "fargate_service_dashboard" {
  source                         = "git@github.com:theorchard/terraform-datadog.git//modules/service//?ref=6.18.2"
  environment                    = var.environment
  environment_type               = "fargate"
  service_name                   = var.service_name
  application_family             = var.application_family
  service_4xx_monitor_enabled    = false
  service_5xx_monitor_enabled    = false
  service_cpu_monitor_silenced   = true
  healthy_tasks_monitor_silenced = true

  notification_endpoints            = var.notification_endpoint
  escalation_notification_endpoints = var.escalation_notification_endpoints
}

data "aws_iam_policy_document" "amazon_music_reporting_access_policy" {
  statement {
    sid = "AthenaControlPlaneForAmazonMusicDB"
    actions = [
      "athena:StartQueryExecution",
      "athena:StopQueryExecution",
      "athena:GetDatabase",
      "athena:GetTableMetadata",
      "athena:ListDatabases",
      "athena:ListTableMetadata"
    ]

    resources = [
      "arn:aws:athena:${var.aws_region}:${data.aws_caller_identity.current.id}:workgroup/*",
      "arn:aws:athena:${var.aws_region}:${data.aws_caller_identity.current.id}:datacatalog/AWSDataCatalog/database/amazon_music_reporting_datalake_link",
      "arn:aws:athena:${var.aws_region}:${data.aws_caller_identity.current.id}:datacatalog/AWSDataCatalog/table/amazon_music_reporting_datalake_link/*"
    ]
  }

  statement {
    sid = "AthenaReadQueryExecutions"
    actions = [
      "athena:GetQueryExecution",
      "athena:GetQueryResults",
      "athena:ListQueryExecutions",
      "athena:GetWorkGroup",
    ]
    resources = ["*"]
  }

  statement {
    actions = [
      "lakeformation:List*",
      "lakeformation:Get*",
    ]

    resources = [
      "*",
    ]
  }

  statement {
    actions = [
      "glue:GetDatabases",
      "glue:SearchTables",
      "glue:GetTables",
      "glue:GetDatabase",
      "glue:GetTable",
      "glue:GetPartitions",
      "glue:GetPartition",
    ]

    resources = [
      "arn:aws:glue:${var.aws_region}:${data.aws_caller_identity.current.id}:catalog",
      "arn:aws:glue:${var.aws_region}:${data.aws_caller_identity.current.id}:table/amazon_music_reporting_datalake_link/*",
      "arn:aws:glue:${var.aws_region}:${data.aws_caller_identity.current.id}:database/amazon_music_reporting_datalake_link",
      "arn:aws:glue:${var.aws_region}:${var.amazon_music_aws_account_id}:table/amazon_music_reporting_datalake/*",
      "arn:aws:glue:${var.aws_region}:${var.amazon_music_aws_account_id}:database/amazon_music_reporting_datalake",
      "arn:aws:glue:${var.aws_region}:${var.amazon_music_aws_account_id}:catalog",
    ]
  }

  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:ListBucket",
      "s3:ListBucketMultipartUploads",
      "s3:ListMultipartUploadParts",
      "s3:AbortMultipartUpload",
    ]
    resources = [
      "arn:aws:s3:::${var.feed_ingestion_data_bucket}",
    ]
  }

  statement {
    actions = [
      "s3:GetObject*",
      "s3:DeleteObject*",
      "s3:PutObject*",
    ]
    resources = [
      "arn:aws:s3:::${var.feed_ingestion_data_bucket}/AmazonDataPulse/*",
    ]
  }

  statement {
    sid = "ListAllBuckets"
    actions = [
      "s3:ListAllMyBuckets",
    ]
    resources = ["*"]
  }
}

resource "aws_iam_role_policy" "amazon_music_reporting_access" {
  name   = "amazon_datapulse_athena_access"
  role   = module.fargate_environment.fargate_task_iam_role_name
  policy = data.aws_iam_policy_document.amazon_music_reporting_access_policy.json
}