module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/swf-feed-ingestion/amazon-unlimited-marketshare/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.secrets_manager_service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

data "aws_iam_policy" "existing_swf_policies" {
  for_each = toset(local.existing_swf_policy_names)
  name     = each.value
}

module "fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                  = var.environment
  service_name                 = var.service_name
  application_family           = var.application_family
  secrets_manager_service_name = var.secrets_manager_service_name
  aws_region                   = var.aws_region
  additional_tags              = var.additional_tags
  commit_sha                   = "latest"
  container_port               = "8080"
  task_type                    = "worker"
  desired_task_count           = 1
  task_cpu                     = 2048
  task_memory                  = 4096
  maximum_capacity             = 1
  minimum_capacity             = 1
  vpc_id                       = module.vpc_info.vpc_id
  non_ecr_image                = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/swf-feed-ingestion:latest"

  iam_managed_policy_attachments = [for policy in data.aws_iam_policy.existing_swf_policies : policy.arn]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      AWS_REGION = var.aws_region
    },
    {
      AMAZON_BFM_SFTP_USERNAME = var.amazon_bfm_sftp_username
    },
    {
      AMAZON_FINETUNES_SFTP_USERNAME = var.amazon_finetunes_sftp_username
    },
    {
      AMAZON_SFTP_HOST = var.amazon_sftp_host
    },
    {
      AMAZON_SFTP_PORT = var.amazon_sftp_port
    },
    {
      AMAZON_ORCHARD_SFTP_USERNAME = var.amazon_orchard_sftp_username
    },
    {
      SWF_DOMAIN = local.swf_domain
    },
    {
      FEED_INGESTION_DATA_BUCKET = var.feed_ingestion_data_bucket
    },
    {
      FEED_INGESTION_TABLE = local.feed_ingestion_table
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      GARCON_FLOW_NAME = var.flow_name
    },
    {
      SENTRY_DSN = module.sentry_project.sentry_key_dsn_public_output
    },
  ]
  secrets = [
    {
      AMAZON_BFM_SFTP_PASSWORD = "${var.environment}/${var.secrets_manager_service_name}/AMAZON_BFM_SFTP_PASSWORD"
    },
    {
      AMAZON_FINETUNES_SFTP_PASSWORD = "${var.environment}/${var.secrets_manager_service_name}/AMAZON_FINETUNES_SFTP_PASSWORD"
    },
    {
      AMAZON_ORCHARD_SFTP_PASSWORD = "${var.environment}/${var.secrets_manager_service_name}/AMAZON_ORCHARD_SFTP_PASSWORD"
    },
    {
      SNOWFLAKE_KEY = "${var.environment}/${var.secrets_manager_service_name}/SNOWFLAKE_KEY"
    },
  ]
}

module "sentry_project" {
  source                       = "git@github.com:theorchard/terraform-sentry.git//?ref=5.1.0"
  service_name                 = var.service_name
  application_family           = var.application_family
  environment                  = var.environment
  teams                        = [var.environment]
  platform                     = "python"
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service//?ref=6.18.2"
  application_family                = var.application_family
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  notification_endpoints            = "@slack-data-alerts-qa"
  escalation_notification_endpoints = ""
}