module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/swf-feed-ingestion/swf-am-streams/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_iam_policy" "existing_swf_policies" {
  for_each = toset(local.existing_swf_policy_names)
  name     = each.value
}

module "fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                  = var.environment
  service_name                 = var.service_name
  secrets_manager_service_name = var.secrets_manager_service_name
  application_family           = var.application_family
  aws_region                   = var.aws_region
  additional_tags              = var.additional_tags
  commit_sha                   = "latest"
  container_port               = "9001"
  task_type                    = "worker"
  desired_task_count           = 1
  task_cpu                     = 8192
  task_memory                  = 16384
  maximum_capacity             = 1
  minimum_capacity             = 1
  task_ephemeral_storage_size  = "100"
  vpc_id                       = module.vpc_info.vpc_id
  non_ecr_image                = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/swf-feed-ingestion:latest"

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    for policy in data.aws_iam_policy.existing_swf_policies : policy.arn
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      AWS_REGION = var.aws_region
    },
    {
      BFM_VENDOR_PROP_FILE = var.bfm_vendor_prop_file
    },
    {
      DKUA_VENDOR_PROP_FILE = var.dkua_vendor_prop_file
    },
    {
      FEED_INGESTION_DATA_BUCKET = var.feed_ingestion_data_bucket
    },
    {
      FEED_INGESTION_DROP_BUCKET = var.feed_ingestion_drop_bucket
    },
    {
      FEED_INGESTION_SNS_TOPIC = var.feed_ingestion_sns_topic
    },
    {
      FEED_INGESTION_TABLE = var.feed_ingestion_table
    },
    {
      FINETUNES_VENDOR_PROP_FILE = var.finetunes_vendor_prop_file
    },
    {
      IODA_VENDOR_PROP_FILE = var.ioda_vendor_prop_file
    },
    {
      ORCHARD_VENDOR_PROP_FILE = var.orchard_vendor_prop_file
    },
    {
      PHONOFILE_VENDOR_PROP_FILE = var.phonofile_vendor_prop_file
    },
    {
      REPORTER_JAR = var.reporter_jar
    },
    {
      SME_VENDOR_PROP_FILE = var.sme_vendor_prop_file
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      GARCON_FLOW_NAME = var.flow_name
    },
    {
      CONSUMER_DB = var.consumer_db
    },
    {
      CONSUMER_SCHEMA = var.consumer_schema
    },
  ]

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.secrets_manager_service_name}/SENTRY_DSN"
    },
    {
      SNOWFLAKE_KEY = "${var.environment}/${var.secrets_manager_service_name}/SNOWFLAKE_KEY"
    }
  ]
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.secrets_manager_service_name
  secret_name        = each.value
  application_family = var.application_family
}

module "secret_for_accesstoken" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment        = var.environment
  service_name       = "itunesconnect"
  secret_name        = "AccessToken"
  application_family = var.application_family
}

module "secret_for_accesstoken_altafonte" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment        = var.environment
  service_name       = "itunesconnect"
  secret_name        = "AccessToken_altafonte"
  application_family = var.application_family
}

data "aws_iam_policy_document" "accesstoken_secrets" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [
      module.secret_for_accesstoken.secret_arn,
      module.secret_for_accesstoken_altafonte.secret_arn,
    ]
  }
}

resource "aws_iam_policy" "accesstoken_secrets_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-accesstoken-RO"
  policy = data.aws_iam_policy_document.accesstoken_secrets.json
}

resource "aws_iam_role_policy_attachment" "accesstoken_secrets_policy_attachment" {
  role       = module.fargate_environment.fargate_task_iam_execution_role_name
  policy_arn = aws_iam_policy.accesstoken_secrets_policy.arn
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service//?ref=6.18.2"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  service_cpu_monitor_silenced      = true
  healthy_tasks_monitor_enabled     = false
  notification_endpoints            = "@slack-data-alerts-qa"
  escalation_notification_endpoints = ""
}

module "sentry_project" {
  source                       = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"
  service_name                 = var.service_name
  application_family           = var.application_family
  secrets_manager_service_name = var.secrets_manager_service_name
  environment                  = var.environment
  teams                        = [var.environment]
  platform                     = "python"
}

# Deprecated IAM user
resource "aws_iam_user" "iam_user" {
  name = "${var.environment}-swf-am-streams-user"
  tags = local.tags
}