# Allow service to assume role for cross-account Kafka access
data "aws_iam_policy_document" "consumer_assume_role_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    resources = ["arn:aws:iam::662302927201:role/qa-orchard-access"]
  }
}

resource "aws_iam_policy" "consumer_assume_role_policy" {
  name   = "${var.environment}-${var.service_name}-sts-assume-role-policy"
  policy = data.aws_iam_policy_document.consumer_assume_role_policy.json
}

# Allow service to read shared graphql-switchboard secret
data "aws_iam_policy_document" "consumer_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/graphql-switchboard/CONSUMER_SECRET",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/graphql-switchboard/CONSUMER_SECRET*",
    ]
  }

  statement {
    actions = [
      "secretsmanager:GetRandomPassword",
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "consumer_secrets_manager_policy" {
  name   = "${var.environment}-${var.service_name}-shared-secrets-manager-policy"
  policy = data.aws_iam_policy_document.consumer_secrets_manager_policy.json
}

resource "aws_iam_policy" "kinesis_readonly_policy" {
  name   = "${var.environment}-${var.service_name}-kinesis-RO-policy"
  policy = data.aws_iam_policy_document.kinesis_readonly_policy.json
}

data "aws_iam_policy_document" "kinesis_readonly_policy" {
  statement {
    actions = [
      "kinesis:ListShards",
      "kinesis:ListStreams",
      "kinesis:GetShardIterator",
      "kinesis:GetRecords",
      "kinesis:DescribeStream",
      "kinesis:DescribeStreamConsumer",
      "kinesis:DescribeStreamSummary",
    ]

    resources = [
      module.switchboard_kinesis_stream.kinesis_stream_arn,
    ]
  }
}

module "switchboard_producer_owsrequest_policy" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = "switchboard-producer"
}

module "lambda_kinesis_to_kafka" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = var.lambda_kinesis_to_kafka_name

  lambda_description          = "Notifies Kafka about metadata changes"
  lambda_function_timeout     = "300"
  lambda_function_memory_size = "512"
  use_container_image         = true
  vpc_enabled                 = true
  vpc_id                      = data.aws_vpc.vpc.id
  vpc_subnet_ids              = data.aws_subnets.private.ids

  datadog_enabled          = true
  datadog_advanced_enabled = true

  event_source_mapping_enabled           = true
  event_source_mapping_resource_type     = "kinesis"
  event_source_mapping_stream_name       = module.switchboard_kinesis_stream.kinesis_stream_name
  event_source_mapping_batch_size        = "10"
  event_source_mapping_starting_position = "LATEST"

  lambda_function_environment_variables = {
    Environment          = var.environment
    LOGGER_DSN           = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    SENTRY_DSN           = module.lambda_kinesis_to_kafka_sentry.sentry_key_dsn_public_output
    KAFKA_CLUSTER_ARN    = var.switchboard_kafka_arn
    SWITCHBOARD_ROLE_ARN = "arn:aws:iam::662302927201:role/qa-orchard-access"
    GRAPHQL_URL          = "https://qa-graphql-switchboard.theorchard.io/graphql"
    GRAPHQL_SECRET_NAME  = module.graphql_switchboard_secrets["CONSUMER_SECRET"].secret_arn
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.consumer_assume_role_policy.arn,
    aws_iam_policy.kinesis_readonly_policy.arn,
    "arn:aws:iam::437795906767:policy/Dynamo-qa-switchboard-producer-owsrequest",
    aws_iam_policy.consumer_secrets_manager_policy.arn,
  ]
}

module "lambda_kinesis_to_kafka_datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.18.1"

  environment            = var.environment
  service_name           = var.lambda_kinesis_to_kafka_name
  notification_endpoints = var.notification_endpoints
}

module "lambda_kinesis_to_kafka_sentry" {
  source = "git@github.com:theorchard/terraform-sentry//?ref=5.0.0"

  service_name       = var.lambda_kinesis_to_kafka_name
  environment        = var.environment
  platform           = "python"
  application_family = var.application_family
}