terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/timed-release/iam/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

data "aws_lambda_function" "lambda_timed_release_trigger_product_update" {
  function_name = "${var.environment}-lambda-timed-release-trigger-product-update"
}

data "aws_lambda_function" "lambda_timed_release_notify_label_manager" {
  function_name = "${var.environment}-lambda-timed-release-notify-label-manager"
}

# create eventbridge scheduler group
resource "aws_scheduler_schedule_group" "product_update_schedules" {
  name = "${var.environment}-${var.service_name}-product-update-schedules"
}

# create scheduler execution policy
data "aws_iam_policy_document" "scheduler_execution_policy_document" {
  statement {
    effect = "Allow"

    principals {
      type        = "Service"
      identifiers = [
        "scheduler.amazonaws.com",
      ]
    }

    actions = ["sts:AssumeRole"]
  }
}

# create scheduler execution role
resource "aws_iam_role" "lambda_timed_release_scheduling_role" {
  name               = "${var.environment}-${var.service_name}-scheduling-role"
  assume_role_policy = data.aws_iam_policy_document.scheduler_execution_policy_document.json

  tags = {
    environment        = var.environment
    service_name       = var.service_name
    application_family = var.application_family
    terraformed        = true
  }
}

# create invoke lambda policy
data "aws_iam_policy_document" "timed_release_invoke_lambda_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      data.aws_lambda_function.lambda_timed_release_trigger_product_update.arn,
      data.aws_lambda_function.lambda_timed_release_notify_label_manager.arn
    ]
  }
}

# attach invoke lambda policy.
resource "aws_iam_role_policy" "timed_release_invoke_lambda_role_policy" {
  name   = "${var.environment}-timed-release-invoke-lambda-role-policy"
  role   = aws_iam_role.lambda_timed_release_scheduling_role.id
  policy = data.aws_iam_policy_document.timed_release_invoke_lambda_policy_document.json
}

# following iam role/policies are related to workstation scheduler

data "aws_lambda_function" "lambda_timed_release_ws_send_notification" {
  function_name = "${var.environment}-lambda-timed-release-ws-send-notification"
}

# create eventbridge scheduler group for workstation
resource "aws_scheduler_schedule_group" "ws_product_schedules" {
  name = "${var.environment}-${var.service_name}-ws-product-schedules"

  tags = {
    environment        = var.environment
    service_name       = var.service_name
    application_family = var.application_family
    terraformed        = true
  }
}

# reference of the step function for workstation
data "aws_sfn_state_machine" "sfn_ws_scheduled_product_metadata_update" {
  name = "${var.environment}-sfn-ws-scheduled-product-metadata-update"
}

# create ws scheduling policy
data "aws_iam_policy_document" "ws_scheduler_execution_policy_document" {
  statement {
    effect = "Allow"

    principals {
      type        = "Service"
      identifiers = [
        "scheduler.amazonaws.com",
      ]
    }

    actions = ["sts:AssumeRole"]
  }
}

# create ws scheduling role
resource "aws_iam_role" "timed_release_ws_scheduling_role" {
  name               = "${var.environment}-timed-release-ws-scheduling-role"
  assume_role_policy = data.aws_iam_policy_document.ws_scheduler_execution_policy_document.json
}

# create policy for workstation timed release for sfn execution and lambda invocation
data "aws_iam_policy_document" "timed_release_ws_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "states:StartExecution"
    ]
    resources = [
      data.aws_sfn_state_machine.sfn_ws_scheduled_product_metadata_update.arn
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      data.aws_lambda_function.lambda_timed_release_ws_send_notification.arn
    ]
  }
}

# attach the sfn execution and lambda invocation policy to the ws scheduling role for workstation
resource "aws_iam_role_policy" "timed_release_ws_role_policy" {
  name   = "${var.environment}-timed-release-ws-role-policy"
  role   = aws_iam_role.timed_release_ws_scheduling_role.id
  policy = data.aws_iam_policy_document.timed_release_ws_policy_document.json
}