module "encoding_direct_delivery_bucket" {
  for_each = var.physical_location_ids
  source   = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"

  env                = var.environment
  bucket_name        = "${var.direct_delivery_bucket_name_prefix}-physical-location-${each.value}"
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  # delete old versions of the objects after 7 days.
  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 7
    }
  ]

  # archive old versions of the objects after 365 days.
  lifecycle_rules_options_current_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 365
    }
  ]

  # delete incompelte uploads after 7 days.
  lifecycle_rules_abort_incomplete_multipart_upload_days = [
    {
      prefix  = ""
      enabled = true
      days    = 7
    }
  ]
}

data "aws_iam_policy_document" "encoding_direct_delivery_bucket_rw_policy" {
  for_each = module.encoding_direct_delivery_bucket
  statement {
    actions = [
      "s3:HeadObject",
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:GetObjectAttributes",
      "s3:PutObject",
      "s3:PutObjectAcl",
      "s3:DeleteObject",
      "s3:CreateMultipartUpload",
      "s3:GetObjectAttributes",
      "s3:ListBucket",
      "s3:GetBucketLocation",
    ]

    resources = [
      "${module.encoding_direct_delivery_bucket[each.key].s3_bucket_arn_output}/*",
      "${module.encoding_direct_delivery_bucket[each.key].s3_bucket_arn_output}",
    ]
  }
}

resource "aws_iam_policy" "encoding_direct_delivery_bucket_rw_policy" {
  for_each = data.aws_iam_policy_document.encoding_direct_delivery_bucket_rw_policy
  name     = "S3-${var.environment}-${var.direct_delivery_bucket_name_prefix}-physical-location-${each.key}-RW-policy"
  policy   = data.aws_iam_policy_document.encoding_direct_delivery_bucket_rw_policy[each.key].json
}

data "aws_iam_policy_document" "encoding_direct_delivery_bucket_ro_policy" {
  for_each = module.encoding_direct_delivery_bucket
  statement {
    actions = [
      "s3:GetObject",
      "s3:ListBucket",
    ]

    resources = [
      "${module.encoding_direct_delivery_bucket[each.key].s3_bucket_arn_output}/*",
      "${module.encoding_direct_delivery_bucket[each.key].s3_bucket_arn_output}",
    ]
  }
}

resource "aws_iam_policy" "encoding_direct_delivery_bucket_ro_policy" {
  for_each = data.aws_iam_policy_document.encoding_direct_delivery_bucket_ro_policy
  name     = "S3-${var.environment}-${var.direct_delivery_bucket_name_prefix}-physical-location-${each.key}-RO-policy"
  policy   = data.aws_iam_policy_document.encoding_direct_delivery_bucket_ro_policy[each.key].json
}