# some store can use this s3 bucket as its delivery location.
module "s3_store_delivery_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"

  env                = var.environment
  bucket_name        = var.s3_store_delivery_bucket_name
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  # delete old versions of the objects after 7 days.
  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 7
    }
  ]

  # archive old versions of the objects after 365 days.
  lifecycle_rules_options_current_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 365
    }
  ]

  # delete incompelte uploads after 7 days.
  lifecycle_rules_abort_incomplete_multipart_upload_days = [
    {
      prefix  = ""
      enabled = true
      days    = 7
    }
  ]
}

data "aws_iam_policy_document" "s3_store_bucket_rw_policy_document" {
  statement {
    actions = [
      "s3:HeadObject",
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:GetObjectAttributes",
      "s3:PutObject",
      "s3:PutObjectAcl",
      "s3:DeleteObject",
      "s3:CreateMultipartUpload",
      "s3:GetObjectAttributes",
      "s3:ListBucket",
      "s3:GetBucketLocation",
    ]

    resources = [
      "${module.s3_store_delivery_bucket.s3_bucket_arn_output}/*",
      "${module.s3_store_delivery_bucket.s3_bucket_arn_output}",
    ]
  }
}

resource "aws_iam_policy" "s3_store_bucket_rw_policy" {
  name   = "S3-${var.environment}-${var.s3_store_delivery_bucket_name}-RW-policy"
  policy = data.aws_iam_policy_document.s3_store_bucket_rw_policy_document.json
}