module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}


#S3 backend
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/vector/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.0.4"

  environment = var.environment
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        format(
          "arn:aws:iam::%s:role/prod-jenkins-aws-pipeline-agent",
          data.aws_caller_identity.current.account_id
        )
      ]
    }
  }
}

resource "aws_iam_role" "vector_integration_test_role" {
  name               = format("%s-%s-integration-test-role", var.environment, var.service_name)
  description        = "Role assumed by Jenkins for vector integration tests to access Secrets Manager"
  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json

  tags = {
    environment        = var.environment
    application_family = var.application_family
    service_name       = var.service_name
  }
}

data "aws_secretsmanager_secret" "vector_encoder_m2m_token_secret" {
  name = format("%s/vector-encoder/M2M_JWT_ACCESS_TOKEN", var.environment)
}

data "aws_secretsmanager_secret" "vector_delivery_m2m_token_secret" {
  name = format("%s/vector-delivery/M2M_JWT_ACCESS_TOKEN", var.environment)
}

data "aws_iam_policy_document" "vector_integration_test_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      data.aws_secretsmanager_secret.vector_encoder_m2m_token_secret.arn,
      data.aws_secretsmanager_secret.vector_delivery_m2m_token_secret.arn,
    ]
  }

  statement {
    actions = [
      "secretsmanager:GetRandomPassword",
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "vector_integration_test_secrets_manager_policy" {
  name   = format("SecretsManager-%s-%s-integration-test-role-policy", var.environment, var.service_name)
  description = "Grants vector integration tests access to M2M token secrets"
  policy = data.aws_iam_policy_document.vector_integration_test_secrets_manager_policy.json

  tags = {
    environment        = var.environment
    application_family = var.application_family
    service_name       = var.service_name
  }
}

resource "aws_iam_role_policy_attachment" "vector_integration_test_role_policy_attachment" {
  role       = aws_iam_role.vector_integration_test_role.name
  policy_arn = aws_iam_policy.vector_integration_test_secrets_manager_policy.arn
}