module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/vector/sound-recordings-takedown/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.2.0"

  environment = var.environment
}

module "sound_recording_takedown_m2m_secret" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
}

module "sound_recordings_takedown_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secret_names)

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
  secret_name        = each.value
}

module "sound_recordings_takedown_fargate" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws
  }

  environment                  = var.environment
  service_name                 = var.service_name
  application_family           = var.application_family
  aws_region                   = var.aws_region
  non_ecr_image                = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${var.service_name}:latest"
  vpc_id                       = module.vpc_info.vpc_id
  fargate_service_subnets      = module.vpc_info.default_private_subnet_ids
  task_type                    = "worker"
  desired_task_count           = 0
  minimum_capacity             = 0
  maximum_capacity             = 1
  task_cpu                     = 512
  task_memory                  = 1024
  secrets_manager_service_name = var.service_name
  health_check_command         = "python3 --version"
  cloudwatch_event_enabled     = true
  cloudwatch_event_schedule    = "cron(0 11 * * ? *)"

  environment_variables = [
    { ENVIRONMENT                   = var.environment },
    { AWS_REGION                    = var.aws_region },
    { STORE_ID                      = var.store_id },
    { DELIVERY_TYPE                 = var.delivery_type },
    { CONCURRENCY                   = var.concurrency },
    { TIMEOUT                       = var.timeout },
    { SNOWFLAKE_USER                = var.snowflake_user },
    { SNOWFLAKE_ACCOUNT             = var.snowflake_account },
    { SNOWFLAKE_ROLE                = var.snowflake_role },
    { SNOWFLAKE_WAREHOUSE           = var.snowflake_warehouse },
    { SNOWFLAKE_DATABASE            = var.snowflake_database },
    { SNOWFLAKE_SCHEMA              = var.snowflake_schema },
    { MYSQL_HOST                    = var.mysql_host },
    { MYSQL_PORT                    = var.mysql_port },
    { MYSQL_USER                    = var.mysql_user },
    { MYSQL_DATABASE                = var.mysql_database },
    { S3_BUCKET                     = var.s3_bucket_name },
    { S3_TMP_FILE_DIR               = var.s3_tmp_file_dir },
    { S3_EXPECTED_OWNER             = var.s3_expected_owner },
    { EMAIL_SENDER                  = var.email_sender },
    { EMAIL_RECIPIENTS              = var.email_recipients },
    { LOG_LEVEL                     = var.log_level },
    { SEND_UPCS_TO_MASTERS_REGISTRY = var.send_upcs_to_masters_registry },
    { SENTRY_DSN                    = module.sentry_project.sentry_key_dsn_public_output },
  ]

  secrets = [
    {
      MYSQL_PASSWORD = "${var.environment}/${var.service_name}/MYSQL_PASSWORD"
    },
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
    {
      SNOWFLAKE_PRIVATE_KEY_PASSPHRASE = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY_PASSPHRASE"
    },
    {
      DD_API_KEY = "${var.environment}/datadog/DD_API_KEY"
    },
    {
      DD_APP_KEY = "${var.environment}/datadog/DD_APP_KEY"
    },
  ]
}

module "sentry_project" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"
  service_name       = var.service_name
  application_family = var.application_family
  environment        = var.environment
  teams              = [var.environment]
  platform           = "python"
}

data "aws_iam_policy_document" "sound_recordings_takedown_ses_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:ses:us-east-1:437795906767:identity/${var.email_sender}"
    ]
    actions = [
      "ses:SendEmail",
      "ses:SendRawEmail",
    ]
  }
}


resource "aws_iam_role_policy" "sound_recordings_takedown_ses_policy" {
  name   = "${var.environment}-${var.service_name}-SES-policy"
  role   = module.sound_recordings_takedown_fargate.fargate_task_iam_role_name
  policy = data.aws_iam_policy_document.sound_recordings_takedown_ses_policy_document.json
}

data "aws_iam_policy_document" "sound_recordings_takedown_s3_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:PutObject",
      "s3:GetObject",
      "s3:ListBucket",
    ]
    resources = [
      "arn:aws:s3:::${var.s3_bucket_name}",
      "arn:aws:s3:::${var.s3_bucket_name}/${var.s3_tmp_file_dir}*",
    ]
  }
}

resource "aws_iam_role_policy" "sound_recordings_takedown_s3_policy" {
  name   = "${var.environment}-${var.service_name}-S3-policy"
  role   = module.sound_recordings_takedown_fargate.fargate_task_iam_role_name
  policy = data.aws_iam_policy_document.sound_recordings_takedown_s3_policy_document.json
}