provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "shared-orcd-terraform-state"
    key     = "prod/chef-workstation/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

module "secrets_chef_workstation" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.1.0"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

# Secrets manager policy: chef-workstation-secrets-manager-policy
module "chef_workstation_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.3.0"

  secrets = [
    "${var.environment}/${var.service_name}/CLIENT_KEY",
  ]
  action_types = ["read"]
}

# Secrets manager IAM policy: chef_workstation_build_secrets_manager_policy
resource "aws_iam_policy" "chef_workstation_build_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-deploy-policy"
  policy = module.chef_workstation_secrets_manager_policy.policy.json
}

# IAM role: shared-chef-workstation-deploy-role
data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "chef_workstation_deploy_role" {
  name = "${var.environment}-${var.service_name}-deploy-role"

  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "chef_workstation_deploy_role_policy_attachment" {
  role       = aws_iam_role.chef_workstation_deploy_role.name
  policy_arn = aws_iam_policy.chef_workstation_build_secrets_manager_policy.arn
}