module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "shared-orcd-terraform-state"
    key     = "shared/offboarding-automation/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

module "offboarding_automation_auth0_management_credentials" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.auth0_tenants_list)

  environment        = var.environment
  service_name       = var.service_name
  secret_name        = "${each.value}/auth0_management_credentials"
  application_family = var.application_family
}

module "auth0_management_credentials_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.4.0"

  secrets = [
    for tenant in var.auth0_tenants_list :
    "${var.environment}/${var.service_name}/${tenant}/auth0_management_credentials"
  ]
  action_types = ["read"]

  depends_on = [
    module.offboarding_automation_auth0_management_credentials,
  ]
}

resource "aws_iam_policy" "auth0_management_credentials_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-execution-policy"
  policy = module.auth0_management_credentials_secrets_manager_policy.policy.json
}