data "aws_iam_policy_document" "scheduler_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type        = "Service"
      identifiers = ["events.amazonaws.com"]
    }
  }
}

data "aws_iam_policy_document" "scheduler_invoke_sfn_policy_document" {
  statement {
    actions = ["states:StartExecution"]
    resources = [
      aws_sfn_state_machine.sfn_discovery.arn,
      aws_sfn_state_machine.sfn_execution.arn,
      aws_sfn_state_machine.sfn_suspend_discovery.arn,
      aws_sfn_state_machine.sfn_suspend_execution.arn,
      aws_sfn_state_machine.sfn_close.arn,
    ]
  }
}

resource "aws_iam_role" "scheduler_role" {
  name               = "${var.environment}-${var.service_name}-scheduler-role"
  description        = "${var.environment}-${var.service_name}-scheduler-role"
  assume_role_policy = data.aws_iam_policy_document.scheduler_assume_role_policy.json
}

resource "aws_iam_policy" "scheduler_invoke_sfn_policy" {
  name        = "StateMachine-${var.environment}-${var.service_name}-invoke-policy"
  description = "StateMachine-${var.environment}-${var.service_name}-invoke-policy"
  policy      = data.aws_iam_policy_document.scheduler_invoke_sfn_policy_document.json
}

resource "aws_iam_role_policy_attachment" "scheduler_invoke_sfn_policy_attachment" {
  role       = aws_iam_role.scheduler_role.name
  policy_arn = aws_iam_policy.scheduler_invoke_sfn_policy.arn
}

# Discovery schedule
resource "aws_cloudwatch_event_rule" "sfn_discovery_hourly_schedule" {
  name                = "${var.environment}-${var.service_name}-sfn-hourly-schedule"
  description         = "Triggers ${var.environment}-${var.service_name} discovery step function every hour"
  schedule_expression = "rate(1 hour)"
}

resource "aws_cloudwatch_event_target" "sfn_discovery_hourly_target" {
  rule     = aws_cloudwatch_event_rule.sfn_discovery_hourly_schedule.name
  arn      = aws_sfn_state_machine.sfn_discovery.arn
  role_arn = aws_iam_role.scheduler_role.arn
  input    = "{}"
}

# Execution schedule
resource "aws_cloudwatch_event_rule" "sfn_execution_hourly_schedule" {
  name                = "${var.environment}-${var.service_name}-execution-sfn-hourly-schedule"
  description         = "Triggers ${var.environment}-${var.service_name} execution step function every hour"
  schedule_expression = "rate(1 hour)"
}

resource "aws_cloudwatch_event_target" "sfn_execution_hourly_target" {
  rule     = aws_cloudwatch_event_rule.sfn_execution_hourly_schedule.name
  arn      = aws_sfn_state_machine.sfn_execution.arn
  role_arn = aws_iam_role.scheduler_role.arn
  input    = "{}"
}

# Suspend discovery schedule
resource "aws_cloudwatch_event_rule" "sfn_suspend_discovery_hourly_schedule" {
  name                = "${var.environment}-${var.service_name}-suspend-hourly-schedule"
  description         = "Triggers ${var.environment}-${var.service_name} suspend discovery step function every hour"
  schedule_expression = "rate(1 hour)"
}

resource "aws_cloudwatch_event_target" "sfn_suspend_discovery_hourly_target" {
  rule     = aws_cloudwatch_event_rule.sfn_suspend_discovery_hourly_schedule.name
  arn      = aws_sfn_state_machine.sfn_suspend_discovery.arn
  role_arn = aws_iam_role.scheduler_role.arn
  input    = "{}"
}

# Suspend execution schedule
resource "aws_cloudwatch_event_rule" "sfn_suspend_execution_hourly_schedule" {
  name                = "${var.environment}-${var.service_name}-suspend-execution-hourly-schedule"
  description         = "Triggers ${var.environment}-${var.service_name} suspend execution step function every hour"
  schedule_expression = "rate(1 hour)"
}

resource "aws_cloudwatch_event_target" "sfn_suspend_execution_hourly_target" {
  rule     = aws_cloudwatch_event_rule.sfn_suspend_execution_hourly_schedule.name
  arn      = aws_sfn_state_machine.sfn_suspend_execution.arn
  role_arn = aws_iam_role.scheduler_role.arn
  input    = "{}"
}

# Close schedule
resource "aws_cloudwatch_event_rule" "sfn_close_hourly_schedule" {
  name                = "${var.environment}-${var.service_name}-close-hourly-schedule"
  description         = "Triggers ${var.environment}-${var.service_name} close step function every hour"
  schedule_expression = "rate(1 hour)"
}

resource "aws_cloudwatch_event_target" "sfn_close_hourly_target" {
  rule     = aws_cloudwatch_event_rule.sfn_close_hourly_schedule.name
  arn      = aws_sfn_state_machine.sfn_close.arn
  role_arn = aws_iam_role.scheduler_role.arn
  input    = "{}"
}