data "aws_lambda_function" "datadog_lambda_function" {
  function_name = "DatadogLambdaFunction"
}

data "aws_iam_policy_document" "sfn_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
        "lambda.amazonaws.com",
      ]
    }
  }
}

data "aws_iam_policy_document" "sfn_invoke_lambda_and_fargate_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_auth0_cli.lambda_arn,
      module.lambda_dynamo_cli.lambda_arn,
      module.lambda_github_cli.lambda_arn,
      module.lambda_jira_cli.lambda_arn,
    ]
  }
}

data "aws_iam_policy_document" "sfn_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${aws_cloudwatch_log_group.sfn_discovery_log_group.arn}:*",
      "${aws_cloudwatch_log_group.sfn_execution_log_group.arn}:*",
      "${aws_cloudwatch_log_group.sfn_suspend_discovery_log_group.arn}:*",
      "${aws_cloudwatch_log_group.sfn_suspend_execution_log_group.arn}:*",
      "${aws_cloudwatch_log_group.sfn_close_log_group.arn}:*",
    ]

    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]
  }

  # These log-delivery actions are account-level operations that do not support
  # resource-level permissions — "resources = *" is required per AWS docs.
  # https://docs.aws.amazon.com/step-functions/latest/dg/cw-logs.html
  statement {
    effect = "Allow"
    resources = [
      "*",
    ]

    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
    ]
  }
}

resource "aws_iam_role" "sfn_role" {
  name               = "${var.environment}-${var.service_name}-sfn-role"
  description        = "${var.environment}-${var.service_name}-sfn-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_assume_role_policy.json
}

resource "aws_iam_policy" "sfn_invoke_lambda_and_fargate_policy" {
  name        = "${var.environment}-${var.service_name}-invoke-lambda-policy"
  description = "${var.environment}-${var.service_name}-invoke-lambda-policy"
  policy      = data.aws_iam_policy_document.sfn_invoke_lambda_and_fargate_policy_document.json
}

resource "aws_iam_policy" "sfn_log_event_policy" {
  name        = "${var.environment}-${var.service_name}-sfn-log-policy"
  description = "${var.environment}-${var.service_name}-sfn-log-policy"
  policy      = data.aws_iam_policy_document.sfn_log_event_policy_document.json
}

resource "aws_iam_role_policy_attachment" "sfn_invoke_lambda_and_fargate_policy_attachment" {
  role       = aws_iam_role.sfn_role.name
  policy_arn = aws_iam_policy.sfn_invoke_lambda_and_fargate_policy.arn
}

resource "aws_iam_role_policy_attachment" "sfn_log_event_policy_attachment" {
  role       = aws_iam_role.sfn_role.name
  policy_arn = aws_iam_policy.sfn_log_event_policy.arn
}

# ---- Log groups ----

resource "aws_cloudwatch_log_group" "sfn_discovery_log_group" {
  name              = "/aws/vendedlogs/states/${var.environment}-${var.service_name}-sfn-log-group"
  retention_in_days = 365
}

resource "aws_cloudwatch_log_group" "sfn_execution_log_group" {
  name              = "/aws/vendedlogs/states/${var.environment}-${var.service_name}-execution-sfn-log-group"
  retention_in_days = 365
}

resource "aws_cloudwatch_log_group" "sfn_suspend_discovery_log_group" {
  name              = "/aws/vendedlogs/states/${var.environment}-${var.service_name}-suspend-sfn-log-group"
  retention_in_days = 365
}

resource "aws_cloudwatch_log_group" "sfn_suspend_execution_log_group" {
  name              = "/aws/vendedlogs/states/${var.environment}-${var.service_name}-suspend-execution-sfn-log-group"
  retention_in_days = 365
}

resource "aws_cloudwatch_log_group" "sfn_close_log_group" {
  name              = "/aws/vendedlogs/states/${var.environment}-${var.service_name}-close-sfn-log-group"
  retention_in_days = 365
}

# ---- Datadog log subscription filters ----

resource "aws_cloudwatch_log_subscription_filter" "datadog_discovery_log_filter" {
  name            = "${var.environment}-${var.service_name}-sfn-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_discovery_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_execution_log_filter" {
  name            = "${var.environment}-${var.service_name}-execution-sfn-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_execution_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_suspend_discovery_log_filter" {
  name            = "${var.environment}-${var.service_name}-suspend-sfn-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_suspend_discovery_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_suspend_execution_log_filter" {
  name            = "${var.environment}-${var.service_name}-suspend-execution-sfn-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_suspend_execution_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_close_log_filter" {
  name            = "${var.environment}-${var.service_name}-close-sfn-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_close_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

# ---- State machines ----

resource "aws_sfn_state_machine" "sfn_discovery" {
  name     = "${var.environment}-${var.service_name}-state-machine"
  role_arn = aws_iam_role.sfn_role.arn
  definition = templatefile("${path.module}/sfn_discovery.json", {
    lambda_auth0_cli  = module.lambda_auth0_cli.lambda_name
    lambda_dynamo_cli = module.lambda_dynamo_cli.lambda_name
    lambda_github_cli = module.lambda_github_cli.lambda_name
    lambda_jira_cli   = module.lambda_jira_cli.lambda_name
  })

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_discovery_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }

  tags = {
    # env and service are required in addition to the default tags for Datadog step function tracing to work
    env              = var.environment
    service          = var.service_name
    DD_TRACE_ENABLED = true
  }
}

resource "aws_sfn_state_machine" "sfn_execution" {
  name     = "${var.environment}-${var.service_name}-execution-state-machine"
  role_arn = aws_iam_role.sfn_role.arn
  definition = templatefile("${path.module}/sfn_execution.json", {
    lambda_auth0_cli  = module.lambda_auth0_cli.lambda_name
    lambda_dynamo_cli = module.lambda_dynamo_cli.lambda_name
    lambda_github_cli = module.lambda_github_cli.lambda_name
    lambda_jira_cli   = module.lambda_jira_cli.lambda_name
  })

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_execution_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }

  tags = {
    env              = var.environment
    service          = var.service_name
    DD_TRACE_ENABLED = true
  }
}

resource "aws_sfn_state_machine" "sfn_suspend_discovery" {
  name     = "${var.environment}-${var.service_name}-suspend-state-machine"
  role_arn = aws_iam_role.sfn_role.arn
  definition = templatefile("${path.module}/sfn_suspend_discovery.json", {
    lambda_auth0_cli  = module.lambda_auth0_cli.lambda_name
    lambda_dynamo_cli = module.lambda_dynamo_cli.lambda_name
    lambda_github_cli = module.lambda_github_cli.lambda_name
    lambda_jira_cli   = module.lambda_jira_cli.lambda_name
  })

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_suspend_discovery_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }

  tags = {
    env              = var.environment
    service          = var.service_name
    DD_TRACE_ENABLED = true
  }
}

resource "aws_sfn_state_machine" "sfn_suspend_execution" {
  name     = "${var.environment}-${var.service_name}-suspend-execution-state-machine"
  role_arn = aws_iam_role.sfn_role.arn
  definition = templatefile("${path.module}/sfn_suspend_execution.json", {
    lambda_auth0_cli  = module.lambda_auth0_cli.lambda_name
    lambda_dynamo_cli = module.lambda_dynamo_cli.lambda_name
    lambda_github_cli = module.lambda_github_cli.lambda_name
    lambda_jira_cli   = module.lambda_jira_cli.lambda_name
  })

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_suspend_execution_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }

  tags = {
    env              = var.environment
    service          = var.service_name
    DD_TRACE_ENABLED = true
  }
}

resource "aws_sfn_state_machine" "sfn_close" {
  name     = "${var.environment}-${var.service_name}-close-state-machine"
  role_arn = aws_iam_role.sfn_role.arn
  definition = templatefile("${path.module}/sfn_close.json", {
    lambda_jira_cli = module.lambda_jira_cli.lambda_name
  })

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_close_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }

  tags = {
    env              = var.environment
    service          = var.service_name
    DD_TRACE_ENABLED = true
  }
}