module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.14.1"

  env                = var.environment
  bucket_name        = var.service_name
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  apply_replication_configuration = [{
    prefix                            = ""
    destination_bucket                = "${var.environment}-${var.service_name}-replica"
    storage_class                     = "INTELLIGENT_TIERING"
    enabled                           = true
    delete_marker_replication_enabled = false
  }]

  storage_lens_configuration = {
    enabled                                    = true
    advanced_cost_optimization_metrics_enabled = true
    advanced_data_protection_metrics_enabled   = true
  }
}

data "aws_lambda_function" "datadog_s3_event_forwarder" {
  function_name = "${var.environment}-lambda-datadog-s3-event-forwarder"
}

resource "aws_s3_bucket_notification" "event_notification_configuration" {
  bucket = module.s3_bucket.s3_bucket_name_output

  lambda_function {
    lambda_function_arn = data.aws_lambda_function.datadog_s3_event_forwarder.arn
    events              = ["s3:Replication:OperationFailedReplication"]
  }
}

module "s3_read_write_delete_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.4.0"

  buckets = [{
    bucket = module.s3_bucket.s3_bucket_name_output
  }]
  action_types = ["read", "write", "delete"]
}

# Create policy for read-write access to the S3 bucket
resource "aws_iam_policy" "s3_read_write_policy" {
  name   = "S3-${var.environment}-${var.service_name}-RW"
  policy = module.s3_read_write_delete_policy.policy.json
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/s3?ref=6.13.7"

  environment                       = var.environment
  service_name                      = var.service_name
  application_family                = var.application_family
  teams                             = ["devops"]
  notification_endpoints            = "@slack-backup-alerts"
  escalation_notification_endpoints = "@slack-backup-alerts"

  dashboard_configuration = {
    enabled                       = true
    show_advanced_storage_metrics = true
    show_replication_metrics      = true
    show_activity_metrics         = true
  }
  replication_failures_monitor_configuration = {
    enabled = true
  }
  replication_latency_monitor_configuration = {
    enabled = true
  }
}