data "aws_iam_policy_document" "rds_refresh_secrets_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:ListSecretVersionIds",
      "secretsmanager:GetSecretValue",
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:DescribeSecret"
    ]
    resources = [
      "arn:aws:secretsmanager:*:*:secret:shared/rds-refresh/*/SNOWFLAKE_USER*",
      "arn:aws:secretsmanager:*:*:secret:shared/rds-refresh/*/SNOWFLAKE_PRIVATE_KEY*",
      "arn:aws:secretsmanager:*:*:secret:shared/rds-refresh/*/SNOWFLAKE_PRIVATE_KEY_PASSPHRASE*",
    ]
  }
}

resource "aws_iam_policy" "rds_refresh_secrets_lambda_policy" {
  name        = "${var.environment}-lambda-${var.service_name}-snowflake-refresh-secrets"
  description = "rds_refresh secrets lambda policy"
  policy      = data.aws_iam_policy_document.rds_refresh_secrets_policy_document.json
}

module "lambda_refresh_snowflake" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.3.0"

  environment                                    = var.environment
  lambda_name                                    = "lambda-${var.service_name}-snowflake-refresh"
  application_family                             = var.application_family
  lambda_description                             = "Executes Snowflake refresh scripts"
  use_container_image                            = true
  datadog_advanced_enabled                       = true
  vpc_enabled                                    = true
  splitio_enabled                                = false
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids
  lambda_function_timeout                        = 600
  lambda_function_reserved_concurrent_executions = 50

  iam_managed_policy_attachments = [
    aws_iam_policy.rds_refresh_secrets_lambda_policy.arn
  ]

  lambda_function_environment_variables = {
    Environment  = var.environment
    SERVICE_NAME = "lambda-${var.service_name}-snowflake-refresh"
    SENTRY_DSN   = module.sentry_project.sentry_key_dsn_public_output
  }
}