data "aws_lambda_function" "datadog_lambda_function" {
  function_name = "DatadogLambdaFunction"
}

data "aws_iam_policy_document" "sfn_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
        "lambda.amazonaws.com",
      ]
    }
  }
}

data "aws_iam_policy_document" "sfn_invoke_lambda_and_fargate_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_get_db_info.lambda_arn,
      module.lambda_delete_intermediate_snapshots.lambda_arn,
      module.lambda_manage_kafka_connector.lambda_arn,
      module.lambda_refresh_snowflake.lambda_arn,
      module.lambda_fivetran_sync.lambda_arn,
    ]

  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:RunTask",
    ]
    resources = [
      module.fargate_create_shareable_snapshot.fargate_task_definition_arn_without_revision,
      "${module.fargate_create_shareable_snapshot.fargate_task_definition_arn_without_revision}:*",
      module.fargate_restore.fargate_task_definition_arn_without_revision,
      "${module.fargate_restore.fargate_task_definition_arn_without_revision}:*",
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:StopTask"
    ]
    resources = [
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task/${var.environment}-${var.service_name}-create-shareable-snapshot/*",
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task/${var.environment}-${var.service_name}-restore/*",
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:DescribeTasks"
    ]
    resources = [
      "*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "events:PutTargets",
      "events:PutRule",
      "events:DescribeRule"
    ]
    resources = [
      "arn:aws:events:${var.region}:${data.aws_caller_identity.current.account_id}:rule/StepFunctionsGetEventsForECSTaskRule"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "iam:PassRole",
    ]
    resources = [
      module.fargate_create_shareable_snapshot.fargate_task_iam_role_arn,
      module.fargate_create_shareable_snapshot.fargate_task_iam_execution_role_arn,
      module.fargate_restore.fargate_task_iam_role_arn,
      module.fargate_restore.fargate_task_iam_execution_role_arn,
    ]
  }
}

data "aws_iam_policy_document" "sfn_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${aws_cloudwatch_log_group.sfn_log_group.arn}:*",
    ]

    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]
  }

  statement {
    effect = "Allow"
    resources = [
      "*",
    ]

    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
    ]
  }
}


resource "aws_iam_role" "sfn_role" {
  name               = "${var.environment}-${var.service_name}-sfn-role"
  description        = "${var.environment}-${var.service_name}-sfn-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_assume_role_policy.json
}

resource "aws_iam_policy" "sfn_invoke_lambda_and_fargate_policy" {
  name        = "${var.environment}-${var.service_name}-invoke-lambda-and-fargate-policy"
  description = "${var.environment}-${var.service_name}-invoke-lambda-and-fargate-policy"
  policy      = data.aws_iam_policy_document.sfn_invoke_lambda_and_fargate_policy_document.json
}

resource "aws_iam_policy" "sfn_log_event_policy" {
  name        = "${var.environment}-${var.service_name}-sfn-log-policy"
  description = "${var.environment}-${var.service_name}-sfn-log-policy"
  policy      = data.aws_iam_policy_document.sfn_log_event_policy_document.json
}

resource "aws_iam_role_policy_attachment" "sfn_invoke_lambda_and_fargate_policy_attachment" {
  role       = aws_iam_role.sfn_role.name
  policy_arn = aws_iam_policy.sfn_invoke_lambda_and_fargate_policy.arn
}

resource "aws_iam_role_policy_attachment" "sfn_log_event_policy_attachment" {
  role       = aws_iam_role.sfn_role.name
  policy_arn = aws_iam_policy.sfn_log_event_policy.arn
}

resource "aws_iam_role_policy_attachment" "sfn_assume_role_policy_attachment" {
  role       = aws_iam_role.sfn_role.name
  policy_arn = aws_iam_policy.assume_target_account_restore_role_policy.arn
}

resource "aws_cloudwatch_log_group" "sfn_log_group" {
  name              = "/aws/vendedlogs/states/${var.environment}-${var.service_name}-sfn-log-group"
  retention_in_days = 365
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_lambda_function_log_filter" {
  name            = "${var.environment}-${var.service_name}-sfn-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

resource "aws_sfn_state_machine" "sfn_rds_refresh" {
  name     = "${var.environment}-${var.service_name}-state-machine"
  role_arn = aws_iam_role.sfn_role.arn
  definition = templatefile("${path.module}/sfn.json", {
    region                                                = var.region
    create_shareable_snapshot_fargate_cluster_arn         = module.fargate_create_shareable_snapshot.fargate_cluster_arn
    create_shareable_snapshot_fargate_task_definition_arn = format("%s:%d",
      module.fargate_create_shareable_snapshot.fargate_task_definition_arn_without_revision,
      var.create_shareable_snapshot_task_revision
    )
    create_shareable_snapshot_fargate_task_security_group = module.fargate_create_shareable_snapshot.fargate_security_group_id
    fargate_task_subnets                                  = jsonencode(module.vpc_info.default_private_subnet_ids)
    lambda_get_db_info_name                               = module.lambda_get_db_info.lambda_name
    lambda_delete_intermediate_snapshots_name             = module.lambda_delete_intermediate_snapshots.lambda_name
    lambda_manage_kafka_connector_name                    = module.lambda_manage_kafka_connector.lambda_name
    lambda_refresh_snowflake_name                         = module.lambda_refresh_snowflake.lambda_name
    lambda_fivetran_sync_name                             = module.lambda_fivetran_sync.lambda_name
    restore_fargate_cluster_arn                           = module.fargate_restore.fargate_cluster_arn
    restore_fargate_task_definition_arn                   = format("%s:%d",
      module.fargate_restore.fargate_task_definition_arn_without_revision,
      var.restore_task_revision
    )
    restore_fargate_task_security_group                   = module.fargate_restore.fargate_security_group_id
    source_account_role                                   = var.source_account_role_name
  })

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }

  tags = {
    # env and service are required in addition to the default tags for Datadog step function tracing to work
    env              = var.environment
    service          = var.service_name
    DD_TRACE_ENABLED = true
  }
}

data "aws_iam_policy_document" "sfn_runner_role_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "sfn_runner_role" {
  name                 = "${var.environment}-${var.service_name}-state-machine-runner-role"
  assume_role_policy   = data.aws_iam_policy_document.sfn_runner_role_assume_role_policy.json
  max_session_duration = 10800
}

data "aws_iam_policy_document" "sfn_runner_role_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "states:StartExecution",
    ]
    resources = [
      aws_sfn_state_machine.sfn_rds_refresh.arn
    ]
  }
  statement {
    effect = "Allow"
    actions = [
      "states:DescribeExecution",
    ]
    resources = [
      "arn:aws:states:${var.region}:${data.aws_caller_identity.current.account_id}:execution:${aws_sfn_state_machine.sfn_rds_refresh.name}:*"
    ]
  }
}

resource "aws_iam_role_policy" "sfn_runner_role_policy" {
  name   = "${var.environment}-${var.service_name}-state-machine-runner-role-policy"
  role   = aws_iam_role.sfn_runner_role.id
  policy = data.aws_iam_policy_document.sfn_runner_role_policy_document.json
}